在 Perl/Moose 中，我可以拥有两个具有相互依赖的默认值的属性吗？

Question

我可以在穆斯做这个吗？

package SomeClass;
use Moose;

has start => (
    isa => 'Int',
    is => 'ro',
    lazy => 1,
    default => sub { $_[0]->end },
);

has end => (
    isa => 'Int',
    is => 'ro',
    lazy => 1,
    default => sub { $_[0]->start },
);

...

换句话说，我想要两个名为“start”和“end”的属性，如果只指定其中一个，我希望将另一个设置为相同的值。不指定其中任何一个都是错误的。

这种相互依赖的设置有效吗？

Answer 1

是的，如果您通过验证至少指定了这些值之一来消除无限递归的可能性：

has start => (
    ...
    predicate => 'has_start',
);

has end => (
    ...
    predicate => 'has_end',
);

sub BUILD
{
    my $self = shift;

    die "Need to specify at least one of 'start', 'end'!" if not $self->has_start and not $self->has_end;
}

或者，您可以延迟对默认子项的检查：

has start => (
    ...
    predicate => 'has_start',
    default => sub {
        my $self = shift;
        die "Need to specify at least one of 'start', 'end'!" if not $self->has_end;
        $self->end;
    },
);

has end => (
    ...
    predicate => 'has_end',
    default => sub {
        my $self = shift;
        die "Need to specify at least one of 'start', 'end'!" if not $self->has_start;
        $self->start;
    },
);

Answer 2

就我个人而言，我会利用惰性来确保我不会陷入无限递归：

has start => (
  is => 'ro',
  isa => 'Int',
  lazy => 1,
  default => sub { shift->end },
  predicate => 'has_start',
);

has end => (
  is => 'ro',
  isa => 'Int',
  lazy => 1,
  default => sub { shift->start },
  predicate => 'has_end',
);

sub BUILD {
  my $self = shift;

  die "Need to specify at least one of 'start', 'end'!" 
    unless $self->has_start || $self->has_end;
}