在specman中如何测试变量或结构字段是否存在？

Question

Specman 手册中几乎没有表明人们可以即时确定是否已创建特定变量。 （不询问数组索引或散列成员的测试，这可以通过 contains() 完成）

我只注意到结构名称/路径解析的讨论确实说尝试“保留”结构字段中不存在的结构字段路径解析将导致错误并且_must_be_被注释掉...

我的工作涉及模拟由多个电子代码开发人员不断更新的模型，并且只要有人简单地创建新变量来进一步指定模型和路径，测试台就会失去向后兼容性。 TCM 构建参数。

Answer 1

您可以使用反射接口来完成此操作。在文档中查找“rf_manager”。然而，并不是所有内容都被记录下来......

在这里，我正在测试字段 baz 是否存在：

struct foo {
   bar : int;
};

struct baz {
};

extend sys {
   run() is also {
      var f : foo = new;
      var rf_f : rf_struct = rf_manager.get_exact_subtype_of_instance(f);
      var f_bar_field : rf_field = rf_f.get_field("bar");

      if f_bar_field != NULL {
         message(NONE,"struct 'foo' has a field called 'bar'");
      } else {
         message(NONE,"struct 'foo' doesn't have a field called 'bar'");
      };

      var b : baz = new;
      var rf_b : rf_struct = rf_manager.get_exact_subtype_of_instance(b);
      var b_bar_field : rf_field = rf_b.get_field("bar");

      if b_bar_field != NULL {
         message(NONE,"struct 'baz' has a field called 'bar'");
      } else {
         message(NONE,"struct 'baz' doesn't have a field called 'bar'");
      };

   };
};

这会产生

[...]
Starting the test ...
Running the test ...
[0] sys-@0: struct 'foo' has a field called 'bar'
[0] sys-@0: struct 'baz' doesn't have a field called 'bar'

如果您需要迭代字段，请执行以下操作：

rf_manager.get_exact_subtype_of_instance(whatever).get_declared_fields()