Grails/GORM 以错误的顺序保存

Question

我正在使用 Grails 1.3.6，但在正确级联保存时遇到问题。该问题特别针对具有两个父类的类。我正在尝试的简化版本是这样的：

class Location {
    String city
    static hasMany = [authors: Author, publishers: Publisher]
}

class Author {
    String name
    static belongsTo = [location: Location]
    static hasMany = [books: Book]
}

class Publisher {
    String name
    static belongsTo = [location: Location]
    static hasMany = [books: Book]
}

class Book {
    String title
    static belongsTo = [author: Author, publisher: Publisher]
}

class Srv1Service {

    static transactional = true

    def loadData() {
        def l1 = new Location(city: "London")

        def a1 = new Author(name: "Graham Greene")
        l1.addToAuthors(a1)

        def p1 = new Publisher(name: "Some Press")
        l1.addToPublishers(p1)

        def b1 = new Book(title: "The Comedians")
        a1.addToBooks(b1)
        p1.addToBooks(b1)

        l1.save()
    } 
}

如果我运行上面的 loadData，Book 实例将在 Publisher 实例之前保存，从而导致错误“not-null 属性引用 null 或瞬态值：adhoc.Book.publisher” 。

我尝试过各种不同的方式来定义这种关系，但收效甚微。我已经尝试过临时保存，这确实有效，但我可以看到父表在我保存子数据时更新 - 即位置、作者和出版商都更新到版本 1。（而且我也想保留代码尽可能简单。）我想避免链接表。

任何建议都将不胜感激！

Answer 1

好的，这里的关键是保存从父级到子级级联。当涉及到 Book 时，您会遇到问题，因为 Book 是 Publisher 和 Author 的子项。 GORM 尝试保存位置，位置尝试保存作者，作者尝试保存图书但是保存失败，因为图书有一个临时发布者。

尝试在创建 Book 之前添加一个中间保存：

def loadData() {
    def l1 = new Location(city: "London")

    def a1 = new Author(name: "Graham Greene")
    l1.addToAuthors(a1)

    def p1 = new Publisher(name: "Some Press")
    l1.addToPublishers(p1)
    l1.save() // add this save

    def b1 = new Book(title: "The Comedians")
    a1.addToBooks(b1)
    p1.addToBooks(b1)

    l1.save()
} 

我创建了一个本地 Grails 项目，并将域类添加到此保存中。级联正在按您的预期工作。