XSLT 验证和连接多个变量

Question

我必须在验证多个变量后验证并连接它们。

<xsl:variable name="val1" select="//xpath"/>
<xsl:variable name="val2" select="//xpath"/>
<xsl:variable name="val3" select="//xpath"/>
<xsl:variable name="val4" select="//xpath"/>
<xsl:variable name="val5" select="//xpath"/>

有可用的模板吗？或者任何人都可以帮助我做到这一点。

从评论中更新

我想连接五个值，如下所示：Address、Address1、City、State、Zipcode。如果 Address 丢失，我将得到类似这样的输出：“, address1, city, state, zipcode”。我想去掉第一个逗号。

<xsl:variable name="__add" select="translate(//*/text()[contains(., 'Address')]/following::td[contains(@class, 'fnt')][1], ',', '')"/>

<xsl:variable name="address">
    <xsl:for-each select="$__add | //*/text()[contains(., 'City')]/following::td[contains(@class, 'fnt')][1] | //*/text()[contains(., 'State')]/following::td[contains(@class, 'fnt')][1] | //*/text()[contains(., 'Pincode')]/following::td[contains(@class, 'fnt')][1]">
        <xsl:value-of select="concat(substring(', ', 1 div (position()!=1)), .)"/>
    </xsl:for-each>
</xsl:variable>

Answer 1

在 XSLT 2.0 中： string-join((Address, Address1, City, State, Zipcode), ',')

在 XSLT 1.0 中，假设您按文档顺序输出结果：

<xsl:for-each select="Address | Address1 | City | State | Zipcode">
  <xsl:if test="position() != 1">, </xsl:if>
  <xsl:value-of select="."/>
</xsl:for-each>

如果不在文档中顺序，那么就像 XSLT 1.0 中的许多事情一样，它可能相当乏味。

Answer 2

XSLT 有一个函数

concat(string, string, ...)

，您可以在另一个变量的 select= 属性中

<xsl:variable name="vals" select="{concat($val1,$val2,$vl3,$val4,$val5)}"/>

或任何允许属性值模板（在花括号中）的地方使用该函数。

Answer 3

保留表达式顺序（xsl:sort 指令）并使用 Becker 方法（substring() 第二个参数）的 XSLT 1.0 解决方案：

<xsl:for-each select="Address|Address1|City|State|Zipcode">
   <xsl:sort select="substring-before(
                        '|Address|Address1|City|State|Zipcode|',
                        concat('|',name(),'|')
                     )"/>
   <xsl:value-of select="concat(
                            substring(
                               ', ',
                               1 div (position()!=1)
                            ),
                            .
                         )"/>
</xsl:for-each> 

无法使用 XSLT 是一件痛苦的事情2.0...看多简单！

<xsl:value-of 
     select="Address, Address1, City, State, Zipcode"
     separator=", "/>

注意：XPath 2.0 序列具有隐式的构造顺序。由于 XSLT 2.0 xsl:value-of 指令句柄序列，现在有一个 @separator。

Answer 4

可能这会很有帮助：

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>

    <xsl:template match="/*">
        <xsl:variable name="vMyVars">
            <xsl:apply-templates select="Address | Address1 | City | State | Zipcode" mode="vMyVars"/>
        </xsl:variable>
        <xsl:value-of select="substring($vMyVars, -1, string-length($vMyVars))"/>
    </xsl:template>

    <xsl:template match="*" mode="vMyVars"/>

    <xsl:template match="*[normalize-space()]" mode="vMyVars">
        <xsl:value-of select="."/>
        <xsl:text>, </xsl:text>
    </xsl:template>

</xsl:stylesheet>

应用于此 XML：

<elems>
    <Address>test</Address>
    <Address1>test2</Address1>
    <City>test3</City>
    <State>test4</State>
    <Zipcode>test5</Zipcode>
</elems>

结果将是：

test, test2, test3, test4, test5

对于此 XML：

<elems>
    <Address1>test2</Address1>
    <City>       </City>
    <State>test4</State>
    <Zipcode></Zipcode>
</elems>

结果将是：

test2, test4