如何求解mathematica中递推关系的解析解

Question

我再次遇到如下情况：

RSolve[{f[m, n] == f[m, n - 1] + f[m - 1, n], 
        f[0, n] == 1, f[m, 0] == 1}, 
        f[m, n], {n}]

我尝试使用 RSolve，但出现错误：

RSolve::deqx: Supplied equations are not difference equations 
              of the given functions.

感谢您的帮助！

Answer 1

差分方程和初始条件为

Mathematica（7 和 8）不喜欢求解它......无论有没有初始条件。 RSolve 表达式未计算，

In[1]:= RSolve[{f[m,n]==f[m,n-1]+f[m-1,n],f[0,n]==f[m,0]==1},f[m,n],{m,n}]
        RSolve[{f[m,n]==f[m,n-1]+f[m-1,n]},f[m,n],{m,n}]
Out[1]= RSolve[{f[m,n]==f[-1+m,n]+f[m,-1+n],f[0,n]==f[m,0]==1},f[m,n],{m,n}]
Out[2]= RSolve[{f[m,n]==f[-1+m,n]+f[m,-1+n]},f[m,n],{m,n}]

我知道 Mathematica 使用 生成函数方法（可能除其他外）来解决此类递归问题，但我不知道为什么它失败在如此简单的情况下。

那么让我们手动完成吧。

设 g(x,n) 为 f(m,n) 的生成函数

现在检查 f(m+1,n) x^m 的总和

现在求解简单的代数差分方程：

也可以使用 RSolve

In[3]:= RSolve[g[x,n]-x g[x,n]==g[x,n-1]&&g[x,0]==1/(1-x),g[x,n],n];
        Simplify[%,Element[n,Integers]]
Out[4]= {{g[x,n]->(1-x)^(-1-n)}}

现在提取 x^m 的系数：

In[5]:= SeriesCoefficient[(1 - x)^(-1 - n), {x, 0, m}]
Out[5]= Piecewise[{{(-1)^m*Binomial[-1 - n, m], m >= 0}}, 0]

使用二项式简化

In[6]:= FullSimplify[(-1)^m*Binomial[-n - 1, m] == Binomial[m + n, m], Element[{n,m}, Integers]&&m>0&&n>0 ]
Out[6]= True

所以我们最终得到

这可以使用符号和数字方式进行检查

In[7]:= ff[m_,n_]:=ff[m,n]=ff[m-1,n]+ff[m,n-1]
        ff[0,_]:=1;ff[_,0]:=1
In[9]:= And@@Flatten[Table[ff[m,n]==Binomial[n+m,m],{n,0,20},{m,0,20}]]
Out[9]= True

In[10]:= {f[m,n]==f[m,n-1]+f[m-1,n],f[0,n]==f[m,0]==1}/.f->(Binomial[#1+#2,#1]&)//FullSimplify
Out[10]= {True,True}

Answer 2

不是答案，但似乎正确的形式应该是（注意最后的 {m, n}）：

RSolve[{f[m, n] == f[m, n - 1] + f[m - 1, n], f[0, n] == 1, f[m, 0] == 1}, f[m, n], {m, n}]

Mathematica 对此不进行评估。我认为这根本无法解决这个问题。