如何创建允许用户在 3 种对象类型之间进行选择的 Windows 界面表单？

Question

所以想法是这样的 - 基类是 Animal，派生类是 Bird 和 Dog。我有一个组合框供用户选择他们想要创建的动物。如何在表单级别将所有这些合并并连接在一起（frmAnimal.cs - 公共部分类 frmAnimal：表单）。

根据此决定，它还会影响表单上的其他按钮，例如调用 .Move() 的按钮（一个重写的 Animal 方法），该按钮将根据选择 Bird 或 Dog 作为对象来调用正确的 Move() 方法。对象类型。

这有道理吗？

Answer 1

您想创建并显示一个与选择表单分开的新表单吗？如果是这样，您可以使表单类通用，仅限于动物类型的对象：

public abstract partial class AnimalFormBase<T>:Form where T:Animal {...}

然后您可以从该表单派生以创建特定于动物的表单：

public partial class AnimalForm:AnimalFormBase<Animal> {...}
public partial class BirdForm:AnimalFormBase<Bird> {...}
public partial class DogForm:AnimalFormBase<Dog> {...}

如果您想要相同的表单但不同的控件，我将使上述类派生来自用户控件。然后，当用户更改单选按钮时，您可以删除旧动物类型的控件并将其替换为新动物的控件。无论哪种方式，通用祖先 AnimalFormBase 都可以保存与任何 Animal 相关的功能。从技术上讲，它可以包含控件，但我发现设计器呈现的类中的自定义继承可能会变得混乱。然后，这三种派生形式可以使用基本功能，添加自己的功能，并布置每种形式将呈现给用户的控件。

Answer 2

我的例子是在 vb.net 中（我正在学习 C#，但还没有“在那里”——差异还没有那么大，以至于这没有意义，尽管……），但要点是通用的。您有一个基类 Animal 和一些派生自 Animal 的类。在基类上定义 .Move 方法。然后创建派生类，它继承基类的方法和公共接口。定义 AnimalType 属性以区分动物的类型。对于这个非常简单的示例，我使用了枚举。实际上，这可能是一个枚举，也可能是一个数据库 PK，或其他唯一标识符。请注意，在实践中，我可能不会使 superType Animal 成为与派生类相同的枚举的成员。例如，在数据库中，我可能会将派生对象设为与“父”动物记录相关的“子”记录）：

Public Enum AnimalTypes
    Animal = 1
    Pig = 2
    Human = 3
End Enum

Public Class AnimalBase

    Public Overridable ReadOnly Property AnimalType() As AnimalTypes
        Get
            Return AnimalTypes.Animal
        End Get
    End Property

    Public Sub Move(ByVal X As Integer, ByVal Y As Integer)
        ' . . . You movement code
    End Sub
End Class

现在您的派生类：

Public Class Pig
    Inherits AnimalBase

    Public Overrides ReadOnly Property AnimalType() As AnimalTypes
        Get
            Return AnimalTypes.Pig
        End Get
    End Property

    'A property spcific to the pig class:
    Public ReadOnly Property PigOnEquality() As String
        Get
            Return "Some pigs are more equal!"
        End Get
    End Property
End Class

Public Class Human
    Inherits AnimalBase

    Public Overrides ReadOnly Property AnimalType() As AnimalTypes
        Get
            Return AnimalTypes.Human
        End Get
    End Property

    'A property specific to the Human class:
    Public ReadOnly Property Shotgun() As String
        Get
            Return "Boom!"
        End Get
    End Property
End Class

现在是一个 AnimalFactory 类，它生成动物实例和从类型派生的类动物，作为（再一次......类型动物）：

Public Class AnimalFactory

    Public Shared Function NewAnimal(ByVal AnimalType As AnimalTypes) As AnimalBase
        Select Case AnimalType
            Case AnimalTypes.Animal
                Return New AnimalBase
            Case AnimalTypes.Pig
                Return New Pig
            Case AnimalTypes.Human
                Return New Human
            Case Else
                Return New AnimalBase
        End Select
    End Function

End Class

这里的技巧是，由 AnimalFacorty 返回的派生类是动物类型，但实现了其真实类型的所有属性，如果需要的话，可以转换成他们的真实类型。现在，你的表格。如果您仅访问基类上定义的通用方法，那么您的表单也不必关心返回的动物类型。如果您需要访问特定于派生类的方法，则需要执行转换操作（这在 C# 中与 VB.net 中可能相同（或非常相似）。

我以这种形式抛出了一些非常愚蠢的示例也可能有一些方法可以避免 Select Case（我相信您会知道它是 Switch 语句），但我不知道您在使用代码做什么，所以这只是一个学术练习。

 Public Class AnimalFarm ' My hilarious name for the FORM

     'Member variable for the currently selected instance of AnimalBase
     Private SelectedAnimal As AnimalBase

     Private Sub AnimalFarm_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load

         'Using the enum to populate the comboBox:
         With Me.ComboBox1.Items
             .Add(AnimalTypes.Animal)
             .Add(AnimalTypes.Pig)
             .Add(AnimalTypes.Human)
         End With

     End Sub

     Private Sub ComboBox1_SelectedIndexChanged(ByVal sender As Object, ByVal e As System.EventArgs) Handles ComboBox1.SelectedIndexChanged
         Dim AnimalType As AnimalTypes = Me.ComboBox1.SelectedItem
         Me.OnNewAnimalSelected(AnimalType)
     End Sub

     Private Sub OnNewAnimalSelected(ByVal AnimalType As AnimalTypes)
         SelectedAnimal = AnimalFactory.NewAnimal(AnimalType)

         'The form doesn't case what type of animal is being instantiated, so long
         'as the methods required are defined on the base class:
         MsgBox(SelectedAnimal.AnimalType.ToString)

         'Move the animal a bit, just for kicks:
         SelectedAnimal.Move(NewX, NewY)

         '  . . . But if you NEED the specific TYPE of animal:

         Select Case SelectedAnimal.AnimalType
             Case AnimalTypes.Human
                 Dim NewHuman As Human = CType(SelectedAnimal, Human)
                 MsgBox(NewHuman.Shotgun)

             Case AnimalTypes.Pig
                 Dim Piggy As Pig = CType(SelectedAnimal, Pig)
                 MsgBox(Piggy.PigOnEquality)
             Case Else
                 MsgBox("This Animal has nothing to say . . .")

         End Select
     End Sub

     Private Sub OnMoveAnimal(ByVal X As Integer, ByVal Y As Integer)
         SelectedAnimal.Move(X, Y)
     End Sub

 End Class