如何更改 mIRC 中链接的颜色？

Question

在 mIRC 中，我希望所有链接看起来都像 html 链接（带有下划线的蓝色），以便它们在频道和消息中突出显示。我确信我必须编写一个远程脚本，但我不确定代码是什么。

Answer 1

更新：这适用于文本中匹配的第一个 URL。我无法完全让它与多个链接一起工作。

请注意，修改通道输出有几个副作用，最值得注意的是多个空格将被压缩为一个（类似于 HTML 中空格的处理方式）。如果您使用任何其他修改通道输出的脚本，这可能会干扰甚至覆盖这些脚本。

我之前没有处理过 mIRC 的 RegEx 函数，因此可能有一种更简洁的方法：

on ^*:TEXT:*:#:{
  set -u %tmp.match /((ht|f)tp[s]?:\S+)/i
  if ($regex(links, $1-, %tmp.match) > 0) {
    set -u %tmp.text $regsubex(links, $1-, %tmp.match, $chr(31) $+ $chr(3) $+ 12 $+ \t $+ $chr(3) $+ $chr(31))
    echo $timestamp $chan < $+ $nick $+ > %tmp.text
    halt
  }
}

注释： set -u 在脚本运行后删除变量，< code>$chr(3) 是颜色的控制代码，12 是 URL 蓝色的颜色编号，$chr(31) 是控制下划线代码。

Answer 2

mIRC“捕手”遵循以下规则：

来自帮助文件（/help catcher）：

mIRC 查找以“http://”、“ftp://”、“gopher://”、“www.”和“ftp.”开头的 URL。 mIRC 还会检查以确保地址不会添加到已存在的列表中。超过 256 个字符的地址将被忽略。

正如另一个答案中所述，修改默认行为将导致间距压缩效果，但对于此脚本来说应该不会有太大问题，因为它只会在显示 URL 时触发。 （此外，我使用了 & 前缀，这将使 mIRC 禁用该事件，以防另一个脚本执行了较早的默认文本更改并执行了 /haltdef）

;this is actually needed to bypass mIRC's parsing behavior of strtok(str, ":")
alias urlreg return /((?:(?:(?:http|ftp|gopher)\72\/\/)|(?:www|ftp)\.)\S+)/Sig

;the coloring alias, blue (12), underline (31)
alias urlcolor return $+($chr(3), 12, $chr(31), $1-, $chr(31), $chr(3))

;trigger for the regex event only
on ^&$*:text:$($urlreg):*:{
  ;if we are in a channel, turn nick into @nick if applicable
  var %nick = $iif($chan, $nick($chan, $nick).pnick, $nick)

  ;color all the linkes using the predefined alias above
  var %msgs = $regsubex($1-, $urlreg, $urlcolor(\t))

  ;print the message, default timestamp, highlighting options, and nick coloring
  echo -tcrl normal $iif($chan, $v1, $nick) $+(<, %nick, >) %msgs

  ;prevent mIRC's default echo
  haltdef
}

将变成：

<@FooBar> abc www.example.com abc www.example.com abc www.example.com

变为：

<@FooBar> abc ^12www.example.com abc ^12www.example.com abc ^12www.example.com

编辑：

我对 $target 的使用在我原来的答案中是无效的，这导致了 Commander_keen 所描述的问题。现在这个问题应该得到解决。

Answer 3

我只是想补充一点，它需要使用 //echo 才能将文本输出到正确的通道，否则文本将被发送到状态窗口等。

此外，我会添加 -bf 和 -m 参数以将消息视为正常的用户消息并应用默认的闪烁/蜂鸣设置，否则该消息不会使通道表现得好像有新消息一样。

因此，jnpcl 脚本的总结为 //echo -bfmtrl，即使尊重时间戳设置（即 -t），

Wiz 的解决方案也可能会从其中的一些中受益也发生了变化。

亲切的问候

PS：jnpcl 的脚本滞后于没有 http:// 的 www 链接的 URL 突出显示，并且在查询窗口中突出显示。最后一个问题当然可以通过在 ^*:TEXT:*:?:{ 块上添加第二个 //echo -bfmtl $nick 轻松解决。 $+ $尼克 $+ > %tmp.text，但我想知道是否可以在一个 ON:TEXT 处理程序中完成。

不幸的是，当检测到查询中的链接并且查询中的文本保持原样时，Wiz 的脚本总是最终发送到状态窗口。似乎 $target 不能按预期的查询工作，它使用自己的昵称，但我不知道解决方案。
因此，在 jnpcl 的代码中使用 Wiz 的正则表达式并进行上述改进，最终会在通道中使用以下工作代码并查询 http 和 www 链接等。目前：

;URL highlighting for channels
    on ^*:TEXT:*:#:{
      set -u %tmp.match /((?:(?:(?:http|ftp|gopher)\72\/\/)|(?:www|ftp)\.)\S+)/Sig
      if ($regex(links, $1-, %tmp.match) > 0) {
        set -u %tmp.text $regsubex(links, $1-, %tmp.match, $chr(31) $+ $chr(3) $+ 12 $+ \t $+ $chr(3) $+ $chr(31))
        //echo -bfmtlr $chan < $+ $nick $+ > %tmp.text
        halt
      }
    }

;URL highlighting for queries
    on ^*:TEXT:*:?:{
      set -u %tmp.match /((?:(?:(?:http|ftp|gopher)\72\/\/)|(?:www|ftp)\.)\S+)/Sig
      if ($regex(links, $1-, %tmp.match) > 0) {
        set -u %tmp.text $regsubex(links, $1-, %tmp.match, $chr(31) $+ $chr(3) $+ 12 $+ \t $+ $chr(3) $+ $chr(31))
        //echo -bfmtlr $nick < $+ $nick $+ > %tmp.text
        halt
      }
    }

我很高兴看到 Wiz 的解决方案也可以使用查询。在我看来，这比两个事件块更干净。在那之前，上面的代码应该代表了两者的优点。