如何使用Delphi XE的TEncoding将西里尔文或ShiftJis文本保存到文件？

Question

我正在尝试使用 Delphi XE 将与我的系统不同的代码页（例如西里尔字母）中的一些文本行保存到 TFileStream。但是我找不到任何代码示例来生成这些编码文件？

我尝试使用与 TStrings.SaveToStream 相同的代码，但是我不确定我是否正确实现了它（例如 WriteBom 部分），并且想知道它在其他地方是如何完成的。这是我的代码：

FEncoding := TEncoding.GetEncoding(1251);
FFilePool := TObjectDictionary<string,TFileStream>.Create([doOwnsValues]);

//...

procedure WriteToFile(const aFile, aText: string);
var
  Preamble, Buffer: TBytes;
begin
  // Create the file if it doesn't exist
  if not FFilePool.ContainsKey(aFile) then
  begin
    // Create the file
    FFilePool.Add(aFile, TFileStream.Create(aFile, fmCreate));
    // Write the BOM
    Preamble := FEncoding.GetPreamble;
    if Length(Preamble) > 0 then
     FFilePool[aFile].WriteBuffer(Preamble[0], Length(Preamble));
  end;
  // Write to the file
  Buffer := FEncoding.GetBytes(aText);
  FFilePool[aFile].WriteBuffer(Buffer[0], Length(Buffer));
end;

提前致谢。

Answer 1

不确定您在寻找什么示例；以下内容可能会有所帮助 - 该示例将 unicode 字符串 (SL) 转换为 ANSI 西里尔字母：

procedure SaveCyrillic(SL: TStrings; Stream: TStream);
var
  CyrillicEncoding: TEncoding;

begin
  CyrillicEncoding := TEncoding.GetEncoding(1251);
  try
    SL.SaveToStream(Stream, CyrillicEncoding);
  finally
    CyrillicEncoding.Free;
  end;
end;

Answer 2

如果我理解的话就很简单了。声明一个与 Cyrillic 1251 相似的 AnsiString：

type
  // The code page for ANSI-Cyrillic is 1251
  CyrillicString = type AnsiString(1251);

然后将您的 Unicode 字符串分配给以下之一：

var
  UnicodeText: string;
  CyrillicText: CyrillicString;
....
  CyrillicText := UnicodeText;

然后您可以以传统方式将 CyrillicText 写入流：

if Length(CyrillicText)>0 then
  Stream.WriteBuffer(CyrillicText[1], Length(CyrillicText));

ANSI 编码的文本文件不应有 BOM 。