在 SPARQL 查询中连接语义端点

Question

我正在尝试发出同时使用 bibleontology 和 dbpedia 语义数据库的请求：

PREFIX bibleontology: <http://bibleontology.com/resource/>
PREFIX dbo: <http://dbpedia.org/ontology/>

SELECT ?art ?abstract WHERE { 
bibleontology:Ezra owl:sameAs ?art .
?art dbo:abstract ?abstract .
}

这种请求既不适用于 bibleontology SPARQL 端点，也不适用于 dbpedia SPARQL 端点。请求的各个部分在每个 SPARQL 端点上运行良好。

可以通过这种方式连接数据库吗？

Answer 1

我是 bibleontology.com 的工程师

bibleontology.com 采用了 SPARQL1.1

PREFIX bibleontology: <http://bibleontology.com/resource/>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
SELECT ?art ?abstract
WHERE {
SERVICE <http://bibleontology.com/sparql/> { bibleontology:Ezra owl:sameAs ?art . }
SERVICE <http://dbpedia.org/sparql> { ?art dbo:abstract ?abstract . } }

Answer 2

该查询不适用于 dbpedia 或 bibleontology，因为信息存储在两个不同的数据库中，当您运行 SPARQL 查询时，您基本上会命中其中之一。这意味着您必须从两个数据库下载数据，将它们放入本地三元组存储中，以便能够运行如您所示的 SPARQL 查询。另一种选择是使用可以为您完成此操作的库。

语义 Web 客户端库 将遵循 SPARQL 查询中的所有 URI 并下载来自每个资源的 RDF 数据，以便它可以连接您查询中出现的所有三元组模式并给出答案。

您可以通过一些细微的更改来运行查询：

PREFIX bibleontology: <http://bibleontology.com/resource/>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX dbpedia: <http://dbpedia.org/ontology/> 

SELECT * WHERE { 
bibleontology:Ezra owl:sameAs ?art .
?art dbpedia:abstract ?abstract .
FILTER langMatches( lang(?abstract), "EN" )
} 

更改说明：

1. 包括 owl 和 dbpedia 命名空间
2. ?art dbpedia:abstract ?abstract . you需要匹配 dbpedia:abstract 谓词来获取摘要，而不是 bibleontology:abstract 才能从
3. 我还包含的 dbpedia 获取摘要仅检索英文摘要的过滤器，这当然是可选的。

下载“语义 Web 库”并将查询放入文件（即：query.sparql）后，您可以运行以下命令来测试您的查询：

./semwebquery -sparqlfile query.sparql -retrieveduris -maxsteps 5

所有命令参数均在语义 Web 客户端库文档中进行了解释。

您将得到以下输出：

| ?art                               | ?abstract
| <http://dbpedia.org/resource/Ezra> | "Ezra is a major .... "@en |

Successfully dereferenced URIs: 

http://www.w3.org/2002/07/owl
http://bibleontology.com/data/Ezra
http://dbpedia.org/data/Ezra.xml
http://dbpedia.org/data3/abstract.n3

为了简单起见，我省略了 dbpedia 的长摘要。 “成功取消引用的 URI”列表是图书馆为了回答您的查询而检索的文档。在该库的文档中，您将了解如何在 Java 中以编程方式运行查询。

Answer 3

所有其他答案都是正确的，因为您无法按原样进行查询，因为数据未合并在单个 SPARQL 端点中。如果端点之一支持 SPARQL 1.1 联合查询，那么您可以使用 SERVICE 关键字，如下所示：

PREFIX bibleontology: <http://bibleontology.com/resource/>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>

SELECT ?art ?abstract
WHERE 
{ 
  bibleontology:Ezra owl:sameAs ?art .
  SERVICE <http://dbpedia.org/sparql?default-graph-uri=http://dbpedia.org> { ?art dbo:abstract ?abstract . }
}

您可以将上述查询提交到 bibleontology SPARQL 端点，前提是它支持 >SERVICE 关键字，它将部分查询发送到 DBPedia SPARQL 端点。

即使您的 SPARQL 端点支持 SERVICE 关键字，那么您仍然依赖两个数据集中的相关数据，即圣经本体需要有一个 owl:sameAs 来指向到 DBPedia 资源，以便 SERVICE 子句实际找到任何内容。

或者

如果您的两个端点都不支持 SERVICE 关键字，那么您可以设置本地端点或使用支持 SERVICE 关键字的命令行工具（如果您感兴趣，我会挖掘一些链接）然后发出以下命令：

PREFIX bibleontology: <http://bibleontology.com/resource/>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>

SELECT ?art ?abstract
WHERE 
{ 
  SERVICE <http://bibleontology.com/sparql> { bibleontology:Ezra owl:sameAs ?art . }
  SERVICE <http://dbpedia.org/sparql?default-graph-uri=http://dbpedia.org> { ?art dbo:abstract ?abstract . }
}

如果您的本地工具/端点支持 SERVICE 那么它将能够将查询的相关部分发送到相关端点并在本地进行连接，希望能返回您想要的结果