如何在 vim 中基于大括号定义缩进？

Question

我使用 https://github.com/cakebaker/scss-syntax.vim vim 上的语法高亮 SCSS （或 SASS）文件，这对于语法高亮非常有效。但是，该插件没有附带缩进文件，并且我在编写缩进文件时遇到了麻烦。

我想将缩进设置为如下所示：

但是，如果我这样做 gg= G，我得到：

我怀疑它不理解基于大括号的嵌套缩进。 的所有不同组合

我尝试了set cindent

set nocindent

set autoindent

set smartindent

，并尝试使用以下代码Tab 键 == 4 个空格和 auto -Vim 中大括号后缩进 ，包括

set tabstop=2

set shiftwidth=2

set Expandtab

...但嵌套大括号缩进似乎永远不起作用。

我相信我可能想编写一个自定义缩进文件，而我所需要的只是基于具有嵌套级别的大括号​​的缩进。我该怎么办？如果有人有一个具有类似语法的文件类型的缩进文件，那也很好。

Answer 1

这是一个基于内置 perl 缩进代码（在 indent/perl.vim 中）的快速破解。希望你能用它来实现你想做的事。有关更多详细信息，请参阅 perl 缩进代码或缩进​​目录中的另一个文件中的更详细注释。

setlocal indentexpr=GetMyIndent()
function! GetMyIndent()
    let cline = getline(v:lnum)

    " Find a non-blank line above the current line.
    let lnum = prevnonblank(v:lnum - 1)
    " Hit the start of the file, use zero indent.
    if lnum == 0
        return 0
    endif
    let line = getline(lnum)
    let ind = indent(lnum)

    " Indent blocks enclosed by {}, (), or []
    " Find a real opening brace
    let bracepos = match(line, '[(){}\[\]]', matchend(line, '^\s*[)}\]]'))
    while bracepos != -1
        let brace = strpart(line, bracepos, 1)
        if brace == '(' || brace == '{' || brace == '['
            let ind = ind + &sw
        else
            let ind = ind - &sw
        endif
        let bracepos = match(line, '[(){}\[\]]', bracepos + 1)
    endwhile
    let bracepos = matchend(cline, '^\s*[)}\]]')
    if bracepos != -1
        let ind = ind - &sw
    endif

    return ind
endfunction

将该文件另存为 ~/.vim/indent/something.vim，其中 something 是您的文件类型（将 ~/.vim 替换为路径如果您在 Windows 上，

您可能还想将其粘贴到 vimfiles 中（但前提是没有可能首先加载的其他缩进声明）：

" Only load this indent file when no other was loaded.
if exists("b:did_indent")
    finish
endif
let b:did_indent = 1