Erlang动态supervisor启动gen_server

Question

我有根主管创建其他主管：

start_link() ->
    supervisor:start_link({local, ?MODULE}, ?MODULE, []).

init([]) ->
    RestartStrategy = {one_for_one, 5, 600},
    ListenerSup =
            {popd_listener_sup,
            {popd_listener_sup, start_link, []},
             permanent, 2000, supervisor, [popd_listener]},

    Children = [ListenerSup],

    {ok, {RestartStrategy, Children}}.

我有 gen_server - 监听器。创建主管后，如何使用 popd_listener_sup 主管运行此 gen_server ？

谢谢。

Answer 1

根主管

-module(root_sup).
-behaviour(supervisor).
-export([start_link/0]).
-export([init/1, shutdown/0]).

start_link() ->
     supervisor:start_link({local,?MODULE}, ?MODULE, []).

init(_Args) ->
     RestartStrategy = {one_for_one, 10, 60},
     ListenerSup = {popd_listener_sup,
          {popd_listener_sup, start_link, []},
          permanent, infinity, supervisor, [popd_listener_sup]},
     Children = [ListenerSup],
     {ok, {RestartStrategy, Children}}.    

% supervisor can be shutdown by calling exit(SupPid,shutdown)
% or, if it's linked to its parent, by parent calling exit/1.
shutdown() ->
     exit(whereis(?MODULE), shutdown).
     % or
     % exit(normal).

如果子进程是另一个主管，则子规范中的 Shutdown 应设置为 infinity 以便为子树提供充足的关闭时间，并且 Type > 应该设置为 supervisor，这就是我们所做的。

子主管

-module(popd_listener_sup).
-behaviour(supervisor).
-export([start_link/0]).
-export([init/1]).

start_link() ->
    supervisor:start_link({local,?MODULE}, ?MODULE, []).

init(_Args) ->
    RestartStrategy = {one_for_one, 10, 60},
    Listener = {ch1, {ch1, start_link, []},
            permanent, 2000, worker, [ch1]},
    Children = [Listener],
    {ok, {RestartStrategy, Children}}.

在这里，在子规范中，我们将 Shutdown 的值设置为 2000。整数超时值意味着主管将通过调用 exit(Child,shutdown) 告诉子进程终止，然后等待子进程返回带有原因关闭的退出信号。

来自 Erlang/OTP 文档的监听器

-module(ch1).
-behaviour(gen_server).

% Callback functions which should be exported
-export([init/1]).
-export([handle_cast/2, terminate/2]).

% user-defined interface functions
-export([start_link/0]).

start_link() ->
     gen_server:start_link({local, ?MODULE}, ?MODULE, [], []).

init(_Args) ->
     erlang:process_flag(trap_exit, true),
     io:format("ch1 has started (~w)~n", [self()]),
     % If the initialization is successful, the function
     % should return {ok,State}, {ok,State,Timeout} ..
     {ok, []}.

handle_cast(calc, State) ->
     io:format("result 2+2=4~n"),
     {noreply, State};
handle_cast(calcbad, State) ->
     io:format("result 1/0~n"),
     1 / 0,
     {noreply, State}.

terminate(_Reason, _State) ->
     io:format("ch1: terminating.~n"),
     ok.

：

如果 gen_server 是
监督树并按其排序
主管终止该功能
模块：终止（原因，状态）将
如果满足以下条件，则使用 Reason=shutdown 进行调用
满足以下条件：

• gen_server 已设置为捕获退出信号，并且
• 主管子规范中定义的关闭策略
  是一个整数超时值，不是
  残酷的杀戮。

这就是我们在 Module:init(Args) 中调用 erlang:process_flag(trap_exit, true) 的原因。

示例运行

启动根管理程序：

1> root_sup:start_link().
ch1 has started (<0.35.0>)
{ok,<0.33.0>}

根管理程序运行并自动启动其子进程，在我们的示例中为子管理程序。子supervisor依次启动其子进程；在我们的例子中，我们只有一个孩子，ch1。

让我们让 ch1 评估正常代码：

2> gen_server:cast(ch1, calc).
result 2+2=4
ok

现在一些错误的代码：

3> gen_server:cast(ch1, calcbad).
result 1/0
ok
ch1: terminating.

=ERROR REPORT==== 31-Jan-2011::01:38:44 ===
** Generic server ch1 terminating 
** Last message in was {'$gen_cast',calcbad}
** When Server state == []
** Reason for termination == 
** {badarith,[{ch1,handle_cast,2},
              {gen_server,handle_msg,5},
              {proc_lib,init_p_do_apply,3}]}
ch1 has started (<0.39.0>)
4> exit(normal).
ch1: terminating.
** exception exit: normal

正如您所看到的，子进程 ch1 被子主管 popd_listener_sup 重新启动（注意 < code>ch1 已启动 (<0.39.0>))。

由于我们的 shell 和根管理程序是双向链接的（在根管理程序函数 start_link/0 中调用 supervisor:start_link，而不是 supervisor:start）， exit(normal) 导致根管理程序关闭，但其子进程有一些时间进行清理。