我如何访问内在属性？

Question

我有一个像这样的 perl 变量。 我如何访问内置属性（如“706”）？

my @config = [
        {
        'x' => [ 565, 706 ],
        'y' => [ 122 ],
        'z' => 34,
        'za' => 59,
    }
];

编辑： print Dumper($config[0]); 产量：< code>$VAR1 = undef;

看起来我使用 $config[0][0]->{x}[1]; 获得访问权限。为什么我必须使用 [0][0] （一个很清楚，但他第二个......）？

EDIT2：我很抱歉更改了数据结构，但是给我的定义发生了变化。

Answer 1

您的变量相当于：

my $config = [
    'x', [ 565, 706 ],
    'y', [ 122 ],
    'z', 34,
    'za', 59,
];

因此，如果您想获得 706，您可以执行以下操作：

print $config->[1][1];

根据问题中的新数据更新

有了更新的问题，您现在可以通过以下方式访问：

say $config->[0]{x}[1];

新更新根据新的数据结构

根据您提供的最后更新的数据结构：

my @config = [
        {
        'x' => [ 565, 706 ],
        'y' => [ 122 ],
        'z' => 34,
        'za' => 59,
    }
];

您分配一个匿名数组[...]，它本身包含一个哈希{...}
到数组@config，这将填充@config的第一个元素
对于匿名数组，

say Dumper \@config;

$VAR1 = [
          [
            {
              'y' => [
                       122
                     ],
              'za' => 59,
              'x' => [
                       565,
                       706
                     ],
              'z' => 34
            }
          ]
        ];
say $config[0][0]{x}[1];  #prints 706

我认为您想要执行以下任一操作：

my $config = [
        {
        'x' => [ 565, 706 ],
        'y' => [ 122 ],
        'z' => 34,
        'za' => 59,
    }
];
say $config->[0]{x}[1]; #prints 706



my @config = (
        {
        'x' => [ 565, 706 ],
        'y' => [ 122 ],
        'z' => 34,
        'za' => 59,
    }
);
say $config[0]{x}[1];  #prints 706

Answer 2

[编辑： 遵循转移问题定义。]

给出：

my @config = ( 
  [
    { # NB: insertion order ≠ traversal order
        "x"  => [ 565, 706 ],
        "y"  => [ 122 ],
        "z"  => 34,
        "za" => 59,
    },
  ],
);

那么这就可以了：

# choice §1
print $config[0][0]{"x"}[-1];   # get 1ˢᵗ row’s xᵗʰ row’s last element

当然理解这只是语法糖：

# choice §2
print $config[0]->[0]->{"x"}->[-1];   # get 1ˢᵗ row’s xᵗʰ row’s last element

并且这只是语法糖for:

# choice §3
print ${ $config[0] }[0]->{"x"}->[-1];   # get 1ˢᵗ row’s xᵗʰ row’s last element

反过来又只是语法糖 for:

# choice §4
print ${ ${ $config[0] }[0] }{"x"}->[-1];   # get 1ˢᵗ row’s xᵗʰ row’s last element

又是语法糖 for:

# choice §5
print ${ ${ ${ $config[0] }[0] }{"x"}}[-1];   # get 1ˢᵗ row’s xᵗʰ row’s last element

当然，它等价于：

# choice §6
print ${ ${ ${ $config[0] }[0] }{"x"} }[ $#{ ${ ${ $config[0] }[0] }{"x"} } ];   # get 1ˢᵗ row’s xᵗʰ row’s last element