从包内获取当前上下文

Question

我的笔记本里有类似以下内容。

test1[g_] := (g == 5);
test2[g_] := (g == 6);
tests={"test1", "test2"}
ToExpression[#][5] & /@ tests

当我将此代码放入包中时，它不起作用，因为 test1 现在称为 MyPackage'Private'test1。如何修改最后一行以使此代码在包内和笔记本内运行？

更新 这就是为什么我使用 ToExpression 而不是使用符号。回想起来，也许使用 Symbols 更容易，

我有一个函数，我称之为 getGraphs["LeafFree","Planar",!"Tree",...] 来获取所有图形无叶、平面而不是树木。其中一些字符串是 GraphData 中的类，而其他字符串是我自己的类。对于我自己的每个类，我都有一个具有相同名称的函数，例如测试属性的 LeafFree 。在笔记本中，使用上面的 ToExpression 代码是实现此目的的最快方法。

getGraphs[n_Integer, cl__] := getGraphs[{n, n}, cl];
getGraphs[{nmin_Integer, nmax_Integer}, cl__] := 
 Module[{maxgraphnum = 100},
  customClasses = {"isLeafFree", ! "isLeafFree"};
  classes = {cl}\[Backslash]customClasses;
  builtinClasses = 
   GraphData["Classes"] \[Tilde] (Not /@ GraphData["Classes"]);
  Assert[classes \[Subset] builtinClasses];
  isLeafFree[gname_] := 
   FreeQ[GraphData[gname, "DegreeSequence"], 0 | 1];

  posClasses = Cases[classes\[Backslash]customClasses, _String];
  posGroup = 
   If[posClasses == {}, GraphData[nmin ;; nmax], 
    GraphData[posClasses, nmin ;; nmax]];
  negClasses = classes\[Backslash]posClasses;
  negGroups = GraphData[#[[1]], nmin ;; nmax] & /@ negClasses;

  result = Complement[posGroup, Sequence @@ negGroups];
  customTest[g_] := 
   And @@ (ToExpression[#][g] & /@ ({cl} \[Intersection] 
        customClasses));
  (*result=Take[result,Min[Length[result],100]];*)

  result = Select[result, customTest]
  ]

Answer 1

我同意上面的评论，你也许应该有一个令人信服的理由这样做，但这里是。这是我在这种情况下使用的代码，它允许在运行时在您喜欢的任何上下文中解析您的符号：

SetAttributes[ParseTimeNameSpaceWrapper,HoldFirst];
Options[ParseTimeNameSpaceWrapper] = {
  LocalizingContext->"MyLocalizingContext`",
  DefaultImportedContexts:>{"Imported1`", "Imported2`"},
  ExtraImportedContexts:>   {}
};



ParseTimeNameSpaceWrapper[code_,opts:OptionsPattern[]]:=
Module[{result,
  context = OptionValue[LocalizingContext],
  defcontexts = OptionValue[DefaultImportedContexts],
  extraContexts = OptionValue[ExtraImportedContexts],
  allContexts},
  allContexts = {Sequence@@defcontexts,Sequence@@extraContexts};
  BeginPackage[context,If[allContexts==={},Sequence@@{},allContexts]];      
    result = code;  
  EndPackage[];
  result
]; 

您可以使用选项来指定这些符号存在的某些上下文，您希望在解析阶段导入这些符号。您可以从任何包或笔记本中调用它，并且该符号将根据您指定的任何上下文进行解析。

HTH

编辑：

回应评论（因为它使问题更加具体）：毫无疑问，在运行时 Context[] 将显示调用函数的当前上下文（在这种情况下是全球性的）。我的意思是：Context 有一个语法 Context[symbol]，用于给出任何符号的上下文（如果它位于 $ContextPath 上）。例如，Context[getGraphs] 返回 Bulatov'showGraphs'。因此，如果您需要自动确定某些导出函数的上下文，请调用Context[function]。您可以使用它来构造该包的其他（私有）函数的全名。这是一个独立的示例：

In[1]:= 
BeginPackage["MyTest`"]; 
f[x_, y_, context_: Context[f]] :=
  Module[{f1str = "function1", f2str = "function2", f1, f2}, 
    {f1, f2} = ToExpression[context <> "Private`" <> #] & /@ {f1str, f2str};
    f1[x, y];
    f2[x, y];];

Begin["`Private`"];

function1[x_, y_] :=  Print["In function1: arguments are ", x, " , ", y];
function2[x_, y_] :=  Print["In function2: arguments are ", x, " , ", y];

End[]
EndPackage[];

Out[6]= "MyTest`Private`"

In[8]:= f[1, 2]

During evaluation of In[8]:= In function1: arguments are 1 , 2

During evaluation of In[8]:= In function2: arguments are 1 , 2

其中 x,y 只是一些示例参数。然后，您实际上永远不会提供最后一个参数，但您可以在函数内使用 context 变量，为其他函数构造长名称，如上面的示例代码所示。或者您可以在函数体内简单地使用 Context[f] ，而不向其添加任何参数。

Answer 2

ToExpression 在创建符号时使用 $Context 的当前绑定，因此您可以强制在特定上下文中解释表达式：

Block[{$Context="MyPackage`Private`"}, ToExpression[#][5]] & /@ tests

我不确定我是否理解情况原来的问题。您可以使用 $Context 或 Context[] 获取当前上下文...但 ToExpression 将自动使用当前上下文，无需干预。

如果我在笔记本中运行展示的代码，它工作得很好。如果我像这样运行它：

Begin["MyPackage`Private`"]
test1[g_] := (g == 5);
test2[g_] := (g == 6);
tests = {"test1", "test2"}
ToExpression[#][5] & /@ tests
End[]

...它也工作得很好。如果我像这样运行它，它可能会失败：

(* in the package file *)
Begin["MyPackage`Private`"]
test1[g_] := (g == 5);
test2[g_] := (g == 6);
End[]

(* in the notebook *)
tests = {"test1", "test2"}
ToExpression[#][5] & /@ tests

...这不仅会失败，还会在笔记本的上下文中创建虚假符号。您可以使用上面的Block 配方来解决此问题。

如果您想捕获加载包代码时有效的上下文，您可以执行以下操作：

(* in the package *)
Begin["MyPackage`Private`"]
test1[g_] := (g == 5);
test2[g_] := (g == 6);
tests = {"test1", "test2"};
With[{context = $Context},
  runTests[] := Block[{$Context = context}, ToExpression[#][5]] & /@ tests
]
End[]

(* in the notebook *)
MyPackage`Private`runTests[]

runTests 使用 With 注入私有包上下文进入其定义。

正如 Janus 所指出的，使用符号比使用字符串更好，因为它们会自动管理整个上下文问题 - 但这假设您的实际用例将允许使用符号。