VB 字符串中的转义双引号

Question

我使用以下代码从 VB6 执行 schtasks 命令。执行时，如果文件夹包含空格，则忽略文件夹。例如，"C:\program files\test\test.exe" 将转换为 "c:\program "。我该如何解决这个问题？

MyAppname =  Chr(34) & App.Path & "\" & App.EXEName & ".exe" & Chr(34)
StrCommand = "schtasks /create /sc ONLOGON /RL HIGHEST  /tn myapp  /tr " & MyAppname  
Shell StrCommand, vbHide   

新任务添加为 "c:\program" 而不是 "C:\program files\test\test.exe"

Answer 1

您尝试过使用双引号吗？无论如何，2011 年任何人都不应该受到本机 VB6 shell 命令的限制。这是一个使用 ShellExecuteEx 的函数，用途更加广泛。

Option Explicit

Private Const SEE_MASK_DEFAULT = &H0

Public Enum EShellShowConstants
        essSW_HIDE = 0
        essSW_SHOWNORMAL = 1
        essSW_SHOWMINIMIZED = 2
        essSW_MAXIMIZE = 3
        essSW_SHOWMAXIMIZED = 3
        essSW_SHOWNOACTIVATE = 4
        essSW_SHOW = 5
        essSW_MINIMIZE = 6
        essSW_SHOWMINNOACTIVE = 7
        essSW_SHOWNA = 8
        essSW_RESTORE = 9
        essSW_SHOWDEFAULT = 10
End Enum

Private Type SHELLEXECUTEINFO
        cbSize        As Long
        fMask         As Long
        hwnd          As Long
        lpVerb        As String
        lpFile        As String
        lpParameters  As String
        lpDirectory   As String
        nShow         As Long
        hInstApp      As Long
        lpIDList      As Long     'Optional
        lpClass       As String   'Optional
        hkeyClass     As Long     'Optional
        dwHotKey      As Long     'Optional
        hIcon         As Long     'Optional
        hProcess      As Long     'Optional
End Type

Private Declare Function ShellExecuteEx Lib "shell32.dll" Alias "ShellExecuteExA" (lpSEI As SHELLEXECUTEINFO) As Long

Public Function ExecuteProcess(ByVal FilePath As String, ByVal hWndOwner As Long, ShellShowType As EShellShowConstants, Optional EXEParameters As String = "", Optional LaunchElevated As Boolean = False) As Boolean
    Dim SEI As SHELLEXECUTEINFO

    On Error GoTo Err

    'Fill the SEI structure
    With SEI
        .cbSize = Len(SEI)                  ' Bytes of the structure
        .fMask = SEE_MASK_DEFAULT           ' Check MSDN for more info on Mask
        .lpFile = FilePath                  ' Program Path
        .nShow = ShellShowType              ' How the program will be displayed
        .lpDirectory = PathGetFolder(FilePath)
        .lpParameters = EXEParameters       ' Each parameter must be separated by space. If the lpFile member specifies a document file, lpParameters should be NULL.
        .hwnd = hWndOwner                   ' Owner window handle

        ' Determine launch type (would recommend checking for Vista or greater here also)
        If LaunchElevated = True Then ' And m_OpSys.IsVistaOrGreater = True
            .lpVerb = "runas"
        Else
            .lpVerb = "Open"
        End If
    End With

     ExecuteProcess = ShellExecuteEx(SEI)   ' Execute the program, return success or failure

    Exit Function
Err:
    ' TODO: Log Error
    ExecuteProcess = False
End Function

Private Function PathGetFolder(psPath As String) As String
    On Error Resume Next
    Dim lPos As Long
    lPos = InStrRev(psPath, "\")
    PathGetFolder = Left$(psPath, lPos - 1)
End Function

Answer 2

转义 VB6 或 VBScript 字符串中的引号理论上很简单，但看起来常常令人恐惧。您可以用另一个双引号转义一个双引号。

示例：

“c:\program files\my app\app.exe”

如果我想转义双引号，以便将其传递给 Joe 列出的 shell 执行函数或 VB6 Shell 函数，我会这样写：

escapedString = """c:\program files\my app\app.exe"""

How does这个工作？第一个和最后一个引号将字符串包裹起来，让 VB 知道这是一个字符串。然后，字符串中按字面显示的每个引号都会在其前面添加另一个双引号以对其进行转义。

当您尝试传递带有多个引用部分的字符串时，情况会变得更加疯狂。请记住，您想要传递的每个引用都必须转义。

如果我想将这两个带引号的短语作为由空格分隔的单个字符串传递（这并不罕见）：

"c:\program files\my app\app.exe" "c:\documents and settings\steve"

我会输入：

escapedQuoteHell = """c:\program files\my app\app.exe"" ""c:\documents and settings\steve"""

我已经帮助我的系统管理员使用了一些带有更多引号的 VBScript。

它并不漂亮，但这就是它的工作原理。

Answer 3

另一个例子：

Dim myPath As String = """" & Path.Combine(part1, part2) & """"

祝你好运！