Perl - 我可以获得与脚本驻留位置及其执行位置相关的路径吗？

Question

我正在寻找一种方法来获取两条信息：

• 脚本所在位置的完整路径，包括其文件名
• 执行脚本的完整路径

我知道您可以使用 $0 来获取文件名，但是还有 Perl 原生的其他保留变量可以提供我要查找的内容吗？

我宁愿不使用任何特殊模块，但如果这是唯一的方法，那就这样吧。

Answer 1

使用 FindBin 和 Cwd：

#!/usr/bin/env perl

use strict;
use warnings;

use Cwd        ();
use FindBin    ();
use File::Spec ();

my $full_path = File::Spec->catfile( $FindBin::Bin, $FindBin::Script );
my $executed_from_path = Cwd::getcwd();

print <<OUTPUT;
Full path to script: $full_path
Executed from path:  $executed_from_path
OUTPUT

示例输出（脚本保存为 /tmp/test.pl）：

alanhaggai@love:/usr/share$ /tmp/test.pl 
Full path to script: /tmp/test.pl
Executed from path:  /usr/share

Answer 2

use File::Spec;

print File::Spec->rel2abs($0);

根据需要打印脚本的完整路径，包括文件名。

Answer 3

PWD 环境变量保存当前工作目录，该目录应该是执行脚本的路径。

您可以使用 $ENV{PWD} 和 $0 导出脚本的完整路径

编辑：提供示例代码，因为有些人很难相信这是可能的：

我可能没有捕获所有可能的情况，但这应该非常接近：

use strict;
use warnings;

print "PWD: $ENV{PWD}\n";
print "\$0: $0\n";

my $bin = $0;
my $bin_path;

$bin =~ s#^\./##; # removing leading ./ (if any)

# executed from working directory
if ($bin !~ m#^/|\.\./#) {
  $bin_path = "$ENV{PWD}/$bin";
}
# executed with full path name
elsif ($bin =~ m#^/#) {
  $bin_path = $0;
}
# executed from relative path
else {
  my @bin_path = split m#/#, $bin;
  my @full_path = split m#/#, $ENV{PWD};

  for (@bin_path) {
    next if $_ eq ".";
   ($_ eq "..") ? pop @full_path : push @full_path, $_;
  }
  $bin_path = join("/", @full_path);
}

print "Script Path: $bin_path\n";

测试运行的输出：

PWD: /tmp
$0: ../home/cmatheson/test.pl
Script Path: /home/cmatheson/test.pl

PWD: /home/cam
$0: ./test.pl
Script Path: /home/cam/test.pl

PWD: /usr/local
$0: /home/cam/test.pl
Script Path: /home/cam/test.pl

PWD: /home/cam/Desktop/foo
$0: ../../src/./git-1.7.3.2/../../test.pl
Script Path: /home/cam/test.pl

Answer 4

这可以通过内置的 $FindBin::Bin 变量来实现（参见 perldoc FindBin）：

use FindBin;
use File::Spec;

print "the location of my script is: ", $FindBin::Bin, "\n";
print "the basename of my script is: ", $FindBin::Script, "\n";
print "the full path (symlinks resolved) of my script is: ", File::Spec->catfile($FindBin::RealBin, $FindBin::RealScript), "\n";

Answer 5

您询问了特殊的 Perl 内容，但没有人提到 __FILE__。检查 perldata 以获得更多信息。当我有文件/脚本/模块的相关子树时，我经常使用这个习惯用法 -

use Path::Class qw( file );
use File::Spec;

my $self_file = file( File::Spec->rel2abs(__FILE__) );
print
    " Full path: $self_file", $/,
    "Parent dir: ", $self_file->parent, $/,
    " Just name: ", $self_file->basename, $/;

Answer 6

对于也处理符号链接的解决方案，

use Cwd            qw( realpath );
use File::Basename qw( dirname );

# Look for modules in the same dir as the script.
use lib dirname(realpath($0));

Answer 7

您可以使用核心 Cwd 模块来获取脚本被执行，核心 File::Spec 模块找到脚本的完整路径：

#!perl

use strict;
use warnings;
use Cwd;
use File::Spec;

my $dir = getcwd();
print "Dir: $dir\n";

print "Script: " . File::Spec->rel2abs($0) . "\n";