方案中的偶数总和

Question

这是我第一次接触Scheme。我有一个包含整数的列表，我想获得列表中所有偶数的总和。

 ; sum_even
(define (sum_even l)
  (if (null? l) l
  (cond ((even? (car l)) 0)
        ((not(even? (car l))) (car l)))
  (+ (sum_even (car l) (sum_even(cdr l))))))
(sum_even '(2 3 4))

Answer 1

(define (sum_even l)
    (cond ((null? l) 0)
          ((even? (car l)) (+ (car l) (sum_even (cdr l))))
          (else (sum_even (cdr l)))))

未测试

Answer 2

你并不是在问一个问题。您是否正在检查您的解决方案是否正确或正在寻找替代解决方案？

您还可以通过编辑实现它，如下所示

(apply + (filter even? lst))

：如果正如您所提到的，您不能使用过滤器，则此解决方案将起作用并且是尾递归的：

(define (sum-even lst)
    (let loop ((only-evens lst) (sum 0))
        (cond
            ((null? only-evens) sum)             
            ((even? (car only-evens))
             (loop (cdr only-evens) (+ (car only-evens) sum)))
            (else (loop (cdr only-evens) sum)))))

Answer 3

(define (sum-even xs)
  (foldl (lambda (e acc) 
           (if (even? e) 
               (+ e acc) 
               acc))
         0 
         xs))

例子：

> (sum-even (list 1 2 3 4 5 6 6))
18

Answer 4

这是另一个具有高阶函数并且没有显式递归的函数：

(use srfi-1)

(define (sum-even ls) (fold + 0 (filter even? ls)))

Answer 5

考虑使用内置过滤器功能。例如：

(filter even? l)

将返回列表l中偶数的列表。有很多方法可以对列表中的数字求和（示例取自 http://groups.engin.umd.umich.edu/CIS/course.des/cis400/scheme/listsum.htm）：

;
; List Sum
; By Jerry Smith
;
(define (list-sum lst)
   (cond
     ((null? lst)
       0)
     ((pair? (car lst))
      (+(list-sum (car lst)) (list-sum (cdr lst))))
     (else
       (+ (car lst) (list-sum (cdr lst))))))