拦截单击或双击鼠标 - 仅在双击时执行双击代码

Question

我遇到的情况是，我同时处理单身和单身人士。窗体上的双击鼠标事件。在这两种情况下都必须加载某些内容，但是当发生双击时，我不希望执行附加到单击事件的代码。

有没有办法拦截鼠标单击并检查是双击还是单击，然后适当地执行正确的事件？

也许通过拦截窗口的WndProc什么的？

Answer 1

不，除非您有时间机器，否则这几乎是不可能的。一旦您了解 Windows 如何区分双击和单击，它就变得毫无意义了。

事实证明，Raymond Chen（Windows Shell 团队的开发人员）在标题为“Windows 将单击转换为双击的逻辑结果"。

具体来说，Windows 只知道将某些内容解释为双击，因为在 GetDoubleClickTime 函数。因为它需要千里眼（正如雷蒙德如此雄辩地指出的那样）来提前确定某件事是单击还是双击，所以窗口管理器会继续发送一个 WM_LBUTTONDOWN 消息 一旦收到第一次点击。 WM_LBUTTONDBLCLK 消息仅稍后发送，确认第二次单击实际上代表双击后。结果是，对于收到的每条 WM_LBUTTONDBLCLK 消息，您的应用程序将始终收到两条 WM_LBUTTONDOWN 消息。

现在，.NET Framework 设计人员了解了此过程的工作原理并设计了相应引发的事件。当然，他们无法对双击之前总是发生的单击执行任何操作，但如果确定用户希望将其作为双击事件的一部分，则他们能够抑制第二次单击消息。作为 Control.MouseClick 的文档 事件（大致对应于WM_LBUTTONDOWN 消息）告诉我们：

根据用户操作系统的鼠标设置确定，在时间上足够接近的两次单击将生成 MouseDoubleClick 事件，而不是第二个 MouseClick 事件.

然而，我上面链接的雷蒙德的博客文章确实为坚持双击操作与单击操作无关的设计的应用程序和开发人员提出了一种可能的解决方法（尽管我们都不建议您实际这样做） ）：

现在假设您是一个程序，但仍希望继续采用双击操作与单击操作无关的可疑设计。你做什么？

嗯，您可以做的一件事是，除了在 GetDoubleClickTime() 毫秒。 [已于上午 10 点更正。] 如果您在这段时间内收到 WM_LBUTTONDBLCLK 消息，那么这毕竟是双击。如果不这样做，那么一定是单击了一次，因此您可以执行单击操作（尽管有点晚了）。

Answer 2

这是执行您请求的代码。

Public Class Form1
    Const WM_LBUTTONDOWN As Integer = &H201
    Const WM_LBUTTONDBLCLK As Integer = &H203

    Private WithEvents tmrDoubleClicks As Timer

    Dim isDblClk As Boolean
    Dim firstClickTime As Date
    Dim doubleClickInterval As Integer

    Sub New()

        ' This call is required by the designer.
        InitializeComponent()
        tmrDoubleClicks = New Timer

        ' Add any initialization after the InitializeComponent() call.
        tmrDoubleClicks.Interval = 50
        doubleClickInterval = CInt(Val(Microsoft.Win32.Registry.CurrentUser.
                                       OpenSubKey("Control Panel\Mouse").
                                       GetValue("DoubleClickSpeed", 1000)))
    End Sub

    Protected Overrides Sub Dispose(ByVal disposing As Boolean)
        Try
            If disposing AndAlso components IsNot Nothing Then
                components.Dispose()
            End If
            If disposing AndAlso tmrDoubleClicks IsNot Nothing Then
                tmrDoubleClicks.Dispose()
            End If
        Finally
            MyBase.Dispose(disposing)
        End Try
    End Sub

    Protected Overrides Sub WndProc(ByRef m As System.Windows.Forms.Message)
        Select Case m.Msg
            Case WM_LBUTTONDOWN
                If Not isDblClk Then
                    firstClickTime = Now
                    tmrDoubleClicks.Start()
                End If

            Case WM_LBUTTONDBLCLK
                isDblClk = True
                tmrDoubleClicks.Stop()
                DoubleClickActivity()
                isDblClk = False

            Case Else
                MyBase.WndProc(m)
        End Select
    End Sub

    Private Sub DoubleClickActivity()
        'implement double click activity here
        Dim r As New Random(Now.TimeOfDay.Seconds)
        Me.BackColor = Color.FromArgb(r.Next(0, 255), 
                                      r.Next(0, 255), 
                                      r.Next(0, 255))
    End Sub

    Private Sub SingleClickActivity()
        'implement single click activity here
        Beep()
    End Sub

    Private Sub tmrDoubleClicks_Tick(ByVal sender As Object, 
                                     ByVal e As System.EventArgs 
                                    ) Handles tmrDoubleClicks.Tick

        If Now.Subtract(firstClickTime).TotalMilliseconds > 
          doubleClickInterval Then

            'since there was no other click within the doubleclick speed,
            'stop waiting and fire the single click activity
            isDblClk = False
            tmrDoubleClicks.Stop()
            SingleClickActivity()
        End If
    End Sub
End Class

此代码的关键是延迟触发单击事件，直到双击时间过去。如果在该时间内，另一个点击事件发生，则调用双击事件，而不调用点击事件。但是，如果没有双击，则会调用单击事件。

这种延迟在双击速度较长的计算机上尤其明显。在典型的计算机上，双击速度为 500 毫秒，因此代码将在单击发生后 500 毫秒到 600 毫秒之间运行单击事件。