是否可以同时向多个表添加列？

Question

我正在使用 SQL Server。我想将名为 [DateCreated] 的单个列添加到多个表中。是否可以通过一条语句将此列添加到数据库中的所有表中？

我偶然发现了 Joe Steffaneli 的一个答案，他在其中建议了一个查询，该查询又返回包含 Alter table 语句的行。 查询如下：

select 'alter table ' + quotename(s.name) + '.' + quotename(t.name) + ' add [DateModified] datetime'
    from sys.columns c
        inner join sys.tables t
            on c.object_id = t.object_id
        inner join sys.schemas s
            on t.schema_id = s.schema_id
        left join sys.columns c2
            on t.object_id = c2.object_id
                and c2.name = 'DateModified'
    where c.name = 'DateCreated'
        and t.type = 'U'
        and c2.column_id is null /* DateModified column does not already exist */ 

有什么方法可以执行返回的行吗？对不起英语。

Answer 1

你可能需要这样的东西。在运行脚本之前检查脚本是否执行了您想要的操作（添加默认值为 getdate() 的非空列）！

DECLARE @Dynsql nvarchar(max) 
SET @Dynsql = ''

SELECT @Dynsql = @Dynsql + '
alter table ' + QUOTENAME(SCHEMA_NAME(schema_id))+ '.' + QUOTENAME(name)  + 
' add [DateCreated] datetime not null default getdate()' 
FROM sys.tables
WHERE type='U' and object_id NOT IN (select object_id from sys.columns where name='DateCreated')


EXEC (@Dynsql)

Answer 2

您可以使用此查询
我在此查询中使用 where 子句（可选）来查找所有具有 ID 的表并向其中添加新字段。

您可以更改 where 子句，例如查找具有 BusinessId 列的所有表并添加新字段或删除 where 子句并为所有表添加

DECLARE @SQL varchar(max)

SELECT @SQL= STUFF((SELECT ';' + 'ALTER TABLE ' + t.TABLE_SCHEMA+'.' +t.TABLE_NAME+ ' ADD newfield nvarchar(max)' 

from information_schema.tables t
inner join information_schema.columns c on c.table_name = t.table_name
                                and c.table_schema = t.table_schema
where c.column_name = 'id'
      and t.table_schema not in ('information_schema', 'pg_catalog')
      and t.table_type = 'BASE TABLE'
      FOR XML PATH('')),1,1,'')


EXEC (@SQL)

Answer 3

这个存储过程工作正常

USE databaseName;
exec sp_msforeachtable 'alter table ? Add [DateCreated] datetime not null default getdate()';

Answer 4

declare @i int

set @i=1
while(@i<45)
begin
    declare @sql varchar(200)

    with TempTable as (select Row_number() over(order by stdID) as RowNo,* from SomeTable)

    select @sql= 'alter table Table'+(select Name from TempTable where RowNo=@i)+' add NewColumn int'

    exec (@sql)
    set @i=@i+1
end

Answer 5

不，没有任何一条语句可以将列添加到数据库中的所有表中。

下次请用您正在使用的 RDBMS 标记您的问题。如果有办法的话，我们将无法在不知道您正在使用哪个数据库系统的情况下向您提供命令。