如何在mathematica中绘制长度为n的三角形网格

Question

我想知道是否有人可以帮忙在mathematica中绘制边长为n的三角形网格（等边）。谢谢。

Answer 1

简单的网格：

p = Table[ Table[

    Polygon[{j - 1/2 i, i Sqrt[3]/2} + # & /@ {{0, 0}, {1/2,Sqrt[3]/2}, {1, 0}}],

    {j, i, 9}], {i, 0, 9}];

Graphics[{EdgeForm[Black], FaceForm[White], p}]  

编辑

更清晰的版本，我猜：

s3 = Sqrt[3];
templateTriangleVertex = {{0, 0}, {1, s3}, {2, 0}};

p = Table[Table[

    Polygon[{2 j - i, s3 i } + # & /@ templateTriangleVertex],

    {j, i, 9}], {i, 0, 9}];

Graphics[{EdgeForm[Black], FaceForm[White], p}]

Answer 2

像这样的东西吗？

_{（来源：yaroslavvb.com）}

这是我使用的代码。对于上面的特定任务来说可能太复杂了，它是我必须可视化整数网格的代码的一部分，例如 this< /a>

A = Sqrt[2/3] {Cos[#], Sin[#], Sqrt[1/2]} & /@ 
    Table[Pi/2 + 2 Pi/3 + 2 k Pi/3, {k, 0, 2}] // Transpose;
p2r[{x_, y_, z_}] := Most[A.{x, y, z}];
n = 10;
types = 1/n Permutations /@ IntegerPartitions[n, {3}, Range[1, n]] // 
   Flatten[#, 1] &;
points = p2r /@ types;
Needs["ComputationalGeometry`"]
Graphics[{EdgeForm[Black], FaceForm[Transparent], 
  GraphicsComplex[points, 
   Polygon /@ DelaunayTriangulation[points // N][[All, 2]]]}]

这是做什么

1. 类型包含所有 3 个整数元组，总和为 n。这些整数位于 R^3 的二维子空间上
2. A 是将这些 3 元组旋转到 xy 平面的线性变换
3. Delauney 三角剖分找到连接附近点的所有三角形

Answer 3

这是贝利萨留方法的一种变体。

p = Table[{2 j - i, Sqrt[3] i}, {i, 0, 9}, {j, i, 9}]

Graphics[ Line @ Join[p, Riffle @@@ Partition[p, 2, 1]] ]