最佳实践：方法中的输出参数与复杂返回类型

Question

使用复杂返回类型：

Public Type TimeType
    hours As Integer
    minutes As Integer
End Type

Public Function ParseTimeField(time As String) As TimeType
    Dim timeObject As TimeType
    Dim amountOfDigitHours As Integer

    If time = "" Then time = "0"

    If HasHoursAndMinutesParts(time) Then
        amountOfDigitHours = GetAmountOfDigitHours(time)
        timeObject.hours = CInt(Left(time, amountOfDigitHours))
        timeObject.minutes = CInt(Right(time, 2))
    Else
        timeObject.hours = 0
        timeObject.minutes = CInt(time)
    End If

    ParseTimeField = timeObject
End Function

Private Function HasHoursAndMinutesParts(time As String) As Boolean
    HasHoursAndMinutesParts = Len(time) > 2
End Function

Private Function GetAmountOfDigitHours(time As String) As Integer
    GetAmountOfDigitHours = Len(time) - 2
End Function

调用：

Dim timeObj As TimeType
timeObj = ParseTimeField(strTime)

OR 使用输出参数：

Public Function ParseTimeField(time As String, ByRef hours As Integer, ByRef minutes As Integer)
    Dim timeObject As TimeType
    Dim amountOfDigitHours As Integer

    If time = "" Then time = "0"

    If HasHoursAndMinutesParts(time) Then
        amountOfDigitHours = GetAmountOfDigitHours(time)
        hours = CInt(Left(time, amountOfDigitHours))
        minutes = CInt(Right(time, 2))
    Else
        hours = 0
        minutes = CInt(time)
    End If

    ParseTimeField = timeObject
End Function

Private Function HasHoursAndMinutesParts(time As String) As Boolean
    HasHoursAndMinutesParts = Len(time) > 2
End Function

Private Function GetAmountOfDigitHours(time As String) As Integer
    GetAmountOfDigitHours = Len(time) - 2
End Function

调用：

Dim hours As Integer
Dim minutes As Integer

Call ParseTimeField(strTime, hours, minutes)

顺便说一句，这是 VB6 代码 =)

Answer 1

如果您有单一返回类型，请不要使用 out 参数来返回它。

一般来说，我发现多个 ref/out 参数是代码味道。如果您需要从方法返回数据，最好将其放在一个连贯的对象中。

Answer 2

我有一种感觉，我们会在这个问题上看到不同的观点。不确定是否存在最佳实践。

我通常更喜欢复杂的数据类型，因为我觉得这更符合函数的原始结构，其中输出参数在签名中的输入参数之前。基本上我不喜欢out参数——它们是多余的。每当用编程语言有两种方法做一件事时，就会使不必要的复杂化（我猜我会被 Perl 狂热分子的说法杀死）。您可以使用 return 语句返回数据。时期。

这就是说，当我需要返回两个没有自然分组的参数时，我仍然发现自己经常使用 out 参数 - 即最终会出现在一个仅在该特定函数的返回值中使用的类中。

每当返回数据中有三个或更多参数时，我从不使用 out ，因为我发现调用代码过于冗长 - 需要 Dim 变量（或 C# 中的 var'em）

Answer 3

我倾向于使用 out params 作为通用样式。很少需要实现返回 UDT 的辅助函数，但这些函数通常是模块私有的，因此我也可以将 UDT 的范围保持为模块私有。

在后一种情况下，通常会像这样使用 retval

With ParseTimeField(strTime)
    Debug.Print .hours, .minutes
End With

...并且很可能会将 TimeType 保留在私有范围内。

Answer 4

绝对是见仁见智的问题。我确实时不时地使用 ByRef 参数，特别是对于需要成功/失败类型场景的实用函数。例如，.net 框架中的 TryParse 函数正是执行此操作。您的参数化函数可能如下所示：

Public Function ParseTimeField(time As String, ByRef hours As Integer, ByRef minutes As Integer) As Boolean
    'Do stuff'
    ParseTimeField = True 'or false depending on output success'
End Sub

意味着您可以这样调用它：

Dim hours As Integer
Dim mins as Integer
If ParseTimeField(time, hours, mins) = True Then
    'It worked'
End If

但是，随着事情开始变得更加复杂，并且您实际上返回业务项而不是执行逻辑命令，那么更需要一个单独的类和返回类型。它还使得调用和返回更容易维护。