Haskell 最佳实践：在 Haskeline 中提前终止

Question

我正在使用 Haskeline 包，我想从命令行连续获取三个字符串在我做任何事情之前，我已经想出了对我来说似乎是一个巧妙的解决方案。但我确信可能有更好的方法来做到这一点。我正在寻找使用 Haskeline 包时的最佳实践。请评估以下示例代码的优点：

import System.Console.Haskeline
import Control.Monad.Trans
import Control.Monad.Maybe
import Data.Maybe
import Control.Monad

main :: IO ()
main = runInputT defaultSettings (runMaybeT getStrings) >>= print

getStrings :: MaybeT (InputT IO) (String, String, String)
getStrings = do
   mone <- lift $ getInputLine "food> "
   notNothing mone
   mtwo <- lift $ getInputLine "drink> "
   notNothing mtwo
   mthree <- lift $ getInputLine "dessert> "
   notNothing mthree
   return (fromJust mone, fromJust mtwo, fromJust mthree)
      where
         notNothing a = guard (a /= Nothing)

正如您所看到的，它完成了提前终止的任务，但看起来仍然有点令人讨厌。我正在考虑尝试将 notNothing 和 getInputLine 转换为一行，例如：

mone <- notNothing =<< lift $ getInputLine "food> " -- does not type check

我认为这看起来不错。我认为这是非常清晰和简洁的（尽管它没有类型检查，所以我必须编写一个可以进行类型检查的版本）。

然而，这是我能想到的最好的结果，我的最终问题是：您将如何改进此代码以使其更整洁且更易于阅读？我是否走在正确的轨道上？

编辑：如果你的守卫不是“a /= Nothing”，那么我刚刚发现的一个很好的辅助函数是：

myGuard s = guard (someConditionFunc s) >> s

因为这样你就可以写（如 luqui 建议）：

mone <- myGuard =<< (lift $ getInputLine prompt)

这非常酷。但如果您只匹配 Nothing，那么 TomMD 的答案会更好。

Answer 1

为什么不直接利用 Maybe monad 的 fail _ = Nothing 事实呢？

mthree <- lift $ getInputLine "dessert> "
notNothing mthree

变成

Just mthree <- lift $ getInputLine "dessert> "

Answer 2

辅助功能怎么样？

inputLine :: String -> MaybeT (InputT IO) String
inputLine prompt = do
    m <- lift $ getInputLine prompt
    case m of
        Just x -> return x
        Nothing -> mzero

使用各种技巧可以大大缩短这个时间，但我想澄清一下。现在您可以忘记 getInputLine 可能会失败，MaybeT 会为您解决这个问题。