从 Hold'd 表达式中提取内容的冒险

Question

假设我有一个 param->value 规则列表，其中参数是可能分配有值的符号。例如：

{a, b, c} = {1, 2, 3};
x = Hold[{a->1, b->2, c->3}];

我需要将列表包装在 Hold 中，否则它将计算为 {1->1, 2->2, 3->3}。 （我愿意接受 Hold There 的任何替代方案，如果它能让剩下的事情变得更容易的话。）

现在假设我想将 x 转换成这样：

{"a"->1, "b"->2, "c"->3}

下面的函数将做到这一点：

f[h_] := Block[{a,b,c}, ToString[#[[1]]]->#[[2]]& /@ ReleaseHold@h]

我的问题：你能写一个 f 的版本吗？符号列表 {a,b,c} 不必显式提供？

Answer 1

这是使用 未评估 的方法：

In[1]:= {a, b, c} = {1, 2, 3};

In[2]:= x = Hold[{a -> 1, b -> 2, c -> 3}];

In[3]:= ReleaseHold[
 x /. (symb_ -> e_) :> ToString[Unevaluated[symb]] -> e]

Out[3]= {"a" -> 1, "b" -> 2, "c" -> 3}

Answer 2

{a, b, c} = {1, 2, 3};
x = Hold[{a -> 1, b -> 2, c -> 3}];
f[x_] := Cases[x, HoldPattern[z_ -> y_] :> 
                  StringTake[ToString[(Hold@z)], {6, -2}] -> y, 2];
f[x] // InputForm

Out：

{"a" -> 1, "b" -> 2, "c" -> 3} 

也许不是很优雅，但似乎可行。

Answer 3

这是一个有点老的问题，但我认为有一个答案结合了两者的优点 Andrew Moylan 的回答 和 贝利撒留的回答。您确实希望左侧带有 HoldPattern 的规则列表，而不是包含整个事物的 Hold 规则列表，这样您实际上可以使用规则而无需经历任何类型的ReleaseHold过程。

In[1]:= {a, b, c} = {1, 2, 3};

Unevaluated 也有助于构建您想要的列表类型：

In[2]:= x = Thread[HoldPattern /@ Unevaluated[{a, b, c}] -> Range[3]]
Out[2]= {HoldPattern[a] -> 1, HoldPattern[b] -> 2, HoldPattern[c] -> 3}

现在您可以通过规则替换来执行您想要的操作。这有点复杂，但我发现自己一遍又一遍地做这件事。您可能会注意到，此规则列表几乎与 OwnValues 或 DownValues 列表的形式完全相同，因此能够操作它非常有帮助。诀窍是使用 HoldPattern 和 Verbatim 一致：

In[3]:= f[rules_] :=
         Replace[rules,
          HoldPattern[Verbatim[HoldPattern][s_Symbol] -> rhs_] :>
           With[{string = ToString[Unevaluated[s]]},
            string -> rhs], {1}]

Replace 的级别规范只是为了确保如果 rhs 本身是一条规则或规则列表，不会发生意外情况。

In[4]:= f[x] // InputForm
Out[4]= {"a" -> 1, "b" -> 2, "c" -> 3}