如何使用 Perl 从路径中提取文件名？

Question

我有一个从数据库填充的 Perl 变量。它的名称是$path。我需要获取另一个变量 $file ，它只包含路径名中的文件名。

我尝试过：

$file = $path =~ s/.*\///;

我对 Perl 很陌生。

Answer 1

为什么要重新发明轮子？使用 File::Basename 模块：

use File::Basename;
...
$file = basename($path);

---

为什么 $file=$path= ~s/.*\///; 不起作用？

=~ 的优先级 高于=

因此

$file = $path =~s/.*\///;

被视为：

$file = ($path =~s/.*\///);

在 $path 中进行替换并分配 1 （如果发生替换）或 ''< /code>（如果没有发生替换）。

您想要的是：

($file = $path) =~s/.*\///;

将 $path 的值分配给 $file，然后在 $path 中进行替换。

但这个解决方案同样存在很多问题：

1. 它是不正确的。基于 Unix 的系统（不确定 Windows）中的文件名可以包含换行符。但 . 默认情况下不匹配换行符。因此，您必须使用 s 修饰符，以便 . 也匹配换行符：

   ($file = $path) =~s/.*\///s;
   

2. 最重要的是，它不可移植，因为它假设 /< /code> 是路径分隔符，而某些平台则不然，例如 Windows（使用 \）、Mac（使用 :）。因此，请使用该模块并让它为您处理所有这些问题。

Answer 2

use File::Basename 

检查以下链接以获取有关其工作原理的详细说明：

http://p3rl.org/File::Basename< /a>

Answer 3

我认为最好的方法是 -

use File::Basename;

my $file_name = basename($0);

所以变量 $file_name 将具有脚本的名称

Answer 4

就这么简单：

$path =~ /.*[\/\\](.*)/;    # will return 1 (or 0) and set $1
my $file = $1;              # $1 contains the filename

要检查文件名是否可用，请使用：

$file = $1 if $path =~ /.*[\/\\](.*)/;

模式：

.*[\/\\](.*)
| |     |
| |     \- at last there is a group with the filename
| \------- it's the last / in linux or the last \ in windows
\--------- .* is very greedy, so it takes all it could

使用例如 https://regex101.com/ 进行检查正则表达式。

Answer 5

Path::Class 乍一看可能看起来有点矫枉过正——创建文件和目录对象路径——但它确实可以在复杂的脚本中得到回报，并提供大量的奖励，当你因范围蔓延而陷入困境时，这将防止你陷入困境。 File::Spec 在第一个示例中用于解析路径的乐趣。

use warnings;
use strict;
use Path::Class qw( file );
use File::Spec;

# Get the name of the current script with the procedural interface-
my $self_file = file( File::Spec->rel2abs(__FILE__) );
print
    " Full path: $self_file", $/,
    "Parent dir: ", $self_file->parent, $/,
    " Just name: ", $self_file->basename, $/;

# OO                                    
my $other = Path::Class::File->new("/tmp/some.weird/path-.unk#");
print "Other file: ", $other->basename, $/;

Answer 6

$url=~/\/([^\/]+)$/;
print "Filename $1\n";

Answer 7

对于 Unix 和 Windows 文件系统来说，从路径中提取文件名非常容易，不需要任何包：

my $path;
$path = 'C:\A\BB\C\windows_fs.txt';     # Windows
#$path = '/a/bb/ccc/ddd/unix_fs.txt';    # Unix

my $file =  (split( /\/|\\/, $path))[-1];
print "File: $file\n";

# variable $file is "windows_fs.txt"  for Windows
# variable $file is "unix_fs.txt"     for Unix

逻辑非常简单：创建一个包含路径所有元素的数组并检索最后一个元素。 Perl 允许使用从数组末尾开始的负索引。索引“-1”对应于最后一个元素。