local 与 lambda 的惯用用法？

Question

在HtDP练习30.1.1中，我开始使用 local ，然后将其修改为使用 lambda 来回答这个问题。

(define (add-to-each2 accu a-list)
  (cond
    [(empty? a-list) empty]
    [else (local ((define s (+ accu (first a-list))))
            (cons s (add-to-each2 s (rest a-list))))]))

在

(define (add-to-each5 accu a-list)
  (cond
    [(empty? a-list) empty]
    [else (cons ((lambda (x y)
                   (first (map + (list (first y))
                               (list x)))) accu a-list)
                (add-to-each5 (+ accu (first a-list))(rest a-list)))]))

这个特定的例子中，对我来说，本地版本更容易阅读。是否存在首选 lambda 版本的情况？谢谢。

Answer 1

首先，我认为您可能会将 relative-2-absolute 与 add-to-each 混淆，因为 add-to-each 只是将相同的数字添加到列表的每个元素，而不是递增累加器。本文的其余部分假设情况确实如此，并且只是去掉了增量。

我认为 让 将是我本地绑定的首选。您的 lambda 示例使用一种通用模式，该模式使用 lambda 和 application 模拟 let：

(let ([x e]) body)

相当于：

((lambda (x) body) e)

如果您使用 lambda 的此转换在您的示例中将 更改为 let，您会得到：

(define (add-to-each5 n a-list)
  (cond
    [(empty? a-list) empty]
    [else (cons (let ([x n] [y a-list])
                  (first (map + (list (first y))
                              (list x))))
                (add-to-each5 n (rest a-list)))]))

一个好的编译器可能会为此生成与您的两个示例相同的代码，因此它主要取决于样式。正如您所注意到的，“左-左 lambda”模式可能更难以阅读，所以我更喜欢 let。

但是，练习 30.1.1 试图让您使用 map 来替代每个示例中出现的显式递归。您在示例中使用了 map 但一次仅添加一个，这使得 map 有点痛苦：为什么还要费力包装 (list (first y )) 和 (list x) 当你只想要 (+ (first y) x) 时？

让我们看一下 map 的简单定义，看看它对于解决这个问题有何帮助，而不是痛苦：

(define (map f ls)
  (cond
    [(empty? ls) empty]
    [else (cons (f (first ls)) (map f (rest ls)))]))

马上，您应该注意到与 add-to-each 的一些相似之处code>：cond 的第一行检查是否为空，第二行 cons 与递归中的 first 元素有关调用 rest 上的 map。那么，关键是传递 map 一个 f 来对每个元素执行您想要执行的操作。

对于add-to-each，您希望向每个元素添加一个特定的数字。下面是添加 2 的示例：

> (map (lambda (n) (+ 2 n)) (list 1 2 3 4 5))
(3 4 5 6 7)

请注意，map 和 lambda 均作为 30.1.1 请求，并且它们作用于整个列表，而无需原始add-to-each的显式递归：递归全部抽象在map中。

这应该足以让您找到解决方案；不过，我不想透露最终答案:)