如何在 (emacs) shell 命令的输出中添加颜色？

Question

执行命令 shell-command 时，关联缓冲区中显示的输出不会着色。

当从 emacs 中调用测试框架（输出黄色/绿色/红色...）时，这尤其令人烦恼。

如何配置或扩展 emacs，以便让 shell 命令允许在 shell 中进行彩色输出并在表示该输出时保留颜色？

谢谢！

附：我在 UN*X 系统上使用 Bash shell。

Answer 1

你可以实现你自己的 shell-execute，比如

(defun my-shell-execute(cmd)
   (interactive "sShell command: ")
   (shell (get-buffer-create "my-shell-buf"))
   (process-send-string (get-buffer-process "my-shell-buf") (concat cmd "\n")))

Answer 2

这可能就是您想要的：

(add-hook 'shell-mode-hook 'ansi-color-for-comint-mode-on)

Answer 3

这会添加一条建议，以便在 shell 命令完成后在迷你缓冲区上运行 ansi-color-apply-on-region：

(require 'ansi-color)

(defun ansi-color-apply-on-buffer ()
    (ansi-color-apply-on-region (point-min) (point-max)))

(defun ansi-color-apply-on-minibuffer ()
  (let ((bufs (remove-if-not
               (lambda (x) (string-starts-with (buffer-name x) " *Echo Area"))
               (buffer-list))))
    (dolist (buf bufs)
      (with-current-buffer buf
        (ansi-color-apply-on-buffer)))))

(defun ansi-color-apply-on-minibuffer-advice (proc &rest rest)
  (ansi-color-apply-on-minibuffer))

(advice-add 'shell-command :after #'ansi-color-apply-on-minibuffer-advice)
;; (advice-remove 'shell-command #'ansi-color-apply-on-minibuffer-advice)

它不依赖于 shell 模式或 comint。我将其与类似以下内容一起使用以获得良好的测试输出（带有成功文档测试计数的绿色笑脸。

(defun add-test-function (cmd)
  (interactive "sCommand to run: ")
  (setq my-testall-test-function cmd)
  (defun my-testall ()
    (interactive)
    (shell-command my-testall-test-function))
  (local-set-key [f9] 'my-testall))

Answer 4

此解决方案的灵感来自 @ArneBabenhauserheide，但使用 xterm-color 而不是 ansi-color。它还为 *Shell Command Output* 缓冲区以及迷你缓冲区着色。

(defun xterm-color-colorize-shell-command-output ()
  "Colorize `shell-command' output."
  (let ((bufs
         (seq-remove
          (lambda (x)
            (not (or (string-prefix-p " *Echo Area" (buffer-name x))
                     (string-prefix-p "*Shell Command" (buffer-name x)))))
          (buffer-list))))
    (dolist (buf bufs)
      (with-current-buffer buf
        (xterm-color-colorize-buffer)))))

(defun xterm-color-colorize-shell-command-output-advice (proc &rest rest)
  (xterm-color-colorize-shell-command-output))

(advice-add 'shell-command :after #'xterm-color-colorize-shell-command-output-advice)
;; (advice-remove 'shell-command #'xterm-color-colorize-shell-command-output-advice)