我可以创建一个构造函数来反序列化对象的字符串版本吗？

Question

我正在使用 Delphi 帮助文件中 ComponentToString 部分中的示例序列化和反序列化一个对象（TComponent 后代）。这样我就可以将对象存储在数据库的 VARCHAR 字段中。

当我需要从数据库中存储的字符串实例化类的新实例时，我可以使用 CreateFromString(AOwner: TComponent; AData: String) 形式的构造函数来实现吗？或者我是否必须使用返回组件类实例的非类方法？

如果我可以使用构造函数版本，如何将 ReadComponent 的返回值“映射”到构造函数创建的“self”？

这是帮助文件中的反序列化示例：

function StringToComponentProc(Value: string): TComponent;
var
  StrStream:TStringStream;
  BinStream: TMemoryStream;
begin
  StrStream := TStringStream.Create(Value);
  try
    BinStream := TMemoryStream.Create;
    try
      ObjectTextToBinary(StrStream, BinStream);
      BinStream.Seek(0, soFromBeginning);
      Result:= BinStream.ReadComponent(nil);
    finally
      BinStream.Free;
    end;
  finally
    StrStream.Free;
  end;
end;

Answer 1

一般来说，是的，您可以使构造函数反序列化字符串并使用该信息来初始化新实例。一个简单的例子是具有单个 Integer 字段的类。将字符串传递给构造函数，让构造函数调用 StrToInt 并使用结果初始化字段。

但是，如果您用于反序列化的唯一函数也是创建实例的函数，那么您就不能从构造函数中使用该函数，因为当您只需要一个实例时，您最终会得到两个实例。构造函数不可能说：“没关系；毕竟不要构造实例。我已经在其他地方得到了一个实例。”

但是，这不是您所处的情况。您应该知道， TStream.ReadComponent 允许您自己创建实例。仅当您尚未为其提供要使用的实例时，它才会实例化该类。您应该能够像这样编写构造函数：

constructor TLarryComponent.CreateFromString(const AData: string);
var
  StrStream, BinStream: TStream;
begin
  Create(nil);
  StrStream := TStringStream.Create(AData);
  try
    BinStream := TMemoryStream.Create;
    try
      ObjectTextToBinary(StrStream, BinStream);
      BinStream.Position := 0;
      BinStream.ReadComponent(Self);
    finally
      BinStream.Free;
    end;
  finally
    StrStream.Free;
  end;
end;

我们将由 Self 指定的当前对象传递给 ReadComponent。流将忽略存储在流中的类名，并假定当前对象属于正确的类。

Answer 2

您可以通过类（静态）方法来完成此操作，但不能通过构造函数来完成此操作。
Delphis 的构造函数由编译器内在刚刚创建的实例上调用，该实例已经部分初始化（它是所需的类，并且实例/字段存储已清零）。

如果你查看TStream.ReadComponent的源码，你会发现组件的真实类首先从源流中读取，然后构造一个空实例并由RTTI从流中填充，然后作为结果返回。这意味着：

要使用TStream.ReadComponent，您需要通过RegisterClass将您的类注册到Delphis的流系统。

Answer 3

使用静态类函数而不是构造函数：

type
  TYourClass = class(TComponent)
  public
    class function CreateFromString(AOwner: TComponent; AData: String): TYourClass; static;
  end;

implementation

class function TYourClass.CreateFromString(AOwner: TComponent; AData: String): TYourClass;
begin
   Result := (StringToComponentProc(AData) as TYourClass);
   if AOwner <> nil then
     AOwner.InsertComponent(Result);
end;

AOwner部分可能是个问题，因为TStream.ReadComponent没有所有者的参数。

关于该问题还有另一个问题：

如何指定从 Delphi TStream 读取的组件的所有者？

编辑： 我已经更新了代码示例以包含所有者。

请注意，插入到所有者的组件列表中需要为要插入的组件提供唯一的或空的Name。