在 VB 中重写 GetHashCode 而不支持选中/未选中的关键字？

Question

因此，我试图找出如何在 VB 中为大量自定义对象正确重写 GetHashCode()。经过一番搜索，我找到了 这个精彩的答案。

但有一个问题：VB 缺少 .NET 4.0 中的 checked 和 unchecked 关键字。据我所知，无论如何。因此，使用 Jon Skeet 的实现，我尝试在一个相当简单的类上创建这样的重写，该类具有三个主要成员：Name As String、Value As Int32 和 [类型] 作为 System.Type。因此我想出了：

Public Overrides Function GetHashCode() As Int32
    Dim hash As Int32 = 17

    hash = hash * 23 + _Name.GetHashCode()
    hash = hash * 23 + _Value
    hash = hash * 23 + _Type.GetHashCode()
    Return hash
End Function

问题：Int32 对于像这样的简单对象来说也太小了。我测试的特定实例将“Name”作为一个简单的 5 个字符的字符串，并且该散列本身就足够接近 Int32 的上限，当它尝试计算散列的第二个字段（值）时，它会溢出。因为我找不到 VB 等效项来提供精细的 checked/unchecked 支持，所以我无法解决这个问题。

我也不想删除整个项目中的整数溢出检查。这件事可能已经完成了……40%（我编的，TBH），而且我还有很多代码要写，所以我需要在相当长的一段时间内进行这些溢出检查。

对于 VB 和 Int32，Jon 的 GetHashCode 版本的“安全”版本是什么？或者，.NET 4.0 中是否有 checked/unchecked ，而我在 MSDN 上不容易找到？


编辑：
根据链接的SO问题，最底部不受欢迎的答案提供了一个准解决方案。我说准是因为感觉就像是……作弊。但乞丐不能挑挑拣拣，对吧？

从 C# 转换为更具可读性的 VB 并与上述对象（名称、值、类型）对齐，我们得到：

Public Overrides Function GetHashCode() As Int32
    Return New With { _
        Key .A = _Name, _
        Key .B = _Value, _
        Key .C = _Type
     }.GetHashCode()
End Function

这显然会触发编译器通过生成匿名类型来“作弊”，然后在项目外部对其进行编译命名空间，大概禁用了整数溢出检查，并允许进行数学计算并在溢出时简单地绕回。它似乎还涉及 box 操作码，我知道这会影响性能。不过没有拆箱。

但这提出了一个有趣的问题。我无数次在此处和其他地方看到 VB 和 C# 生成相同的 IL 代码。显然不是 100% 的情况都是如此...就像使用 C# 的 unchecked 关键字只会导致发出不同的操作码。那么，为什么我会继续看到两者产生完全相同的 IL 的假设不断重复？  

无论如何，我宁愿找到一个可以在每个对象模块中实现的解决方案。从 ILDASM 的角度来看，必须为每个对象创建匿名类型会显得很混乱。当我说我的项目中实现了很多类时，我不是在开玩笑。


EDIT2：我确实在 MSFT Connect 上发现了一个错误，VB PM 结果的要点是他们会考虑它，但不要屏住呼吸： https://connect.microsoft.com /VisualStudio/feedback/details/636564/checked-unchecked-keywords-in-visual-basic

快速浏览一下 .NET 4.5 中的变化表明他们还没有考虑过它，所以也许是 .NET 5？

我的最终实现符合 GetHashCode 的限制，同时对于 VB 来说仍然快速且足够独特，如下所示，源自 此页面：

'// The only sane way to do hashing in VB.NET because it lacks the
'// checked/unchecked keywords that C# has.
Public Const HASH_PRIME1 As Int32 = 4
Public Const HASH_PRIME2 As Int32 = 28
Public Const INT32_MASK As Int32 = &HFFFFFFFF

Public Function RotateHash(ByVal hash As Int64, ByVal hashcode As Int32) As Int64
    Return ((hash << HASH_PRIME1) Xor (hash >> HASH_PRIME2) Xor hashcode)
End Function

我还认为“Shift-Add-XOR”哈希也可能适用，但我还没有测试过。

Answer 1

使用 Long 避免溢出：

Dim hash As Long = 17
'' etc..
Return CInt(hash And &H7fffffffL)

And 运算符可确保不会引发溢出异常。然而，这确实会在计算的哈希码中丢失一位“精度”，结果始终为正。 VB.NET 没有内置函数来避免它，但您可以使用一个技巧：

Imports System.Runtime.InteropServices

Module NoOverflows
    Public Function LongToInteger(ByVal value As Long) As Integer
        Dim cast As Caster
        cast.LongValue = value
        Return cast.IntValue
    End Function

    <StructLayout(LayoutKind.Explicit)> _
    Private Structure Caster
        <FieldOffset(0)> Public LongValue As Long
        <FieldOffset(0)> Public IntValue As Integer
    End Structure
End Module

现在您可以编写：

Dim hash As Long = 17
'' etc..
Return NoOverflows.LongToInteger(hash)

Answer 2

这是一个结合了 Hans Passant 的答案 和 乔恩·斯基特的回答。

它甚至适用于数百万个属性（即没有整数溢出异常），并且速度非常快（为具有 1,000,000 个字段的类生成哈希码不到 20 毫秒，而对于只有 100 个字段的类几乎无法测量）。

这是处理溢出的结构：

<StructLayout(LayoutKind.Explicit)>
Private Structure HashCodeNoOverflow
    <FieldOffset(0)> Public Int64 As Int64
    <FieldOffset(0)> Public Int32 As Int32
End Structure

和一个简单的 GetHashCode 函数：

Public Overrides Function GetHashCode() As Integer

    Dim hashCode As HashCodeNoOverflow

    hashCode.Int64 = 17

    hashCode.Int64 = CLng(hashCode.Int32) * 23 + Field1.GetHashCode
    hashCode.Int64 = CLng(hashCode.Int32) * 23 + Field2.GetHashCode
    hashCode.Int64 = CLng(hashCode.Int32) * 23 + Field3.GetHashCode

    Return hashCode.Int32

End Function

或者如果您愿意：

Public Overrides Function GetHashCode() As Integer

    Dim hashCode = New HashCodeNoOverflow With {.Int32 = 17}

    For Each field In Fields
        hashCode.Int64 = CLng(hashCode.Int32) * 23 + field.GetHashCode
    Next

    Return hashCode.Int32

End Function

Answer 3

我在 vb.net 中实现 Skeet 先生的解决方案时遇到了同样的问题。我最终使用 Mod 运算符到达那里。 Integer.MaxValue 的每个 Mod 应仅返回到该点的最不重要的分量，并且始终位于 Integer.MaxValue 和 Integer.MinValue 之内——这应该与未选中的效果相同。你可能不需要像我一样频繁地进行修改（只有当有机会变得比 long 更大时（这意味着组合很多哈希码），然后在最后一次），但是这个的一个变体是有效的对我来说（并且让您可以像其他一些哈希函数一样使用更大的素数而无需担心）。

Public Overrides Function GetHashCode() As Int32
    Dim hash as Int64 = 17
    hash = (hash * 23 + _Name.GetHashCode()) Mod Integer.MaxValue
    hash = (hash * 23 + _Value) Mod Integer.MaxValue
    hash = (hash * 23 + _Type.GetHashCode()) Mod Integer.MaxValue
    Return Convert.ToInt32(hash)
End Function

Answer 4

您可以使用 C# 和 unchecked 关键字或对整个项目进行溢出检查（在 VB.NET 和 C# 项目中都可以）在单独的程序集中实现合适的哈希代码帮助程序。如果您愿意，可以使用 ilmerge 将此程序集合并到主程序集。

Answer 5

改进的答案在VB中覆盖GetHashCode而不检查/取消检查关键字支持？

Public Overrides Function GetHashCode() as Integer
  Dim hashCode as Long = 0
  If myReplacePattern IsNot Nothing Then _
    hashCode = ((hashCode*397) Xor myField.GetHashCode()) And &HffffffffL
  If myPattern IsNot Nothing Then _
    hashCode = ((hashCode*397) Xor myOtherField.GetHashCode()) And &HffffffffL
  Return CInt(hashCode)
End Function

每次乘法后都有一个修剪。 And 字面量显式定义为 Long，因为带有 Integer 参数的 And 运算符不会将高位字节归零。

Answer 6

在研究 VB 没有给我们带来任何类似于 unchecked 的东西并且愤怒了一段时间（c# dev 现在正在做 VB）之后，我实现了一个接近 Hans Passant 发布的解决方案。我失败了。糟糕的表现。这肯定是由于我的实施而不是汉斯发布的解决方案。我本可以回去更仔细地复制他的解决方案。

但是，我用不同的解决方案解决了这个问题。一篇抱怨 VB 语言功能请求页面上缺少 unchecked 的帖子给了我使用框架中已有的哈希算法的想法。在我的问题中，我有一个 String 和 Guid 我想将其用作字典键。我认为 Tuple(Of Guid, String) 将是一个很好的内部数据存储。

原始糟糕版本

Public Structure HypnoKey
  Public Sub New(name As String, areaId As Guid)
    _resourceKey = New Tuple(Of Guid, String)(resourceAreaId, key)
  End Sub

  Private ReadOnly _name As String
  Private ReadOnly _areaId As Guid

  Public ReadOnly Property Name As String
    Get
      Return _name 
    End Get
  End Property

  Public ReadOnly Property AreaId As Guid
    Get
      Return _areaId 
    End Get
  End Property

  Public Overrides Function GetHashCode() As Integer
    'OMFG SO BAD
    'TODO Fail less hard
  End Function

End Structure

大大改进的版本

Public Structure HypnoKey
  Public Sub New(name As String, areaId As Guid)
    _innerKey = New Tuple(Of Guid, String)(areaId , key)
  End Sub

  Private ReadOnly _innerKey As Tuple(Of Guid, String)

  Public ReadOnly Property Name As String
    Get
      Return _innerKey.Item2
    End Get
  End Property

  Public ReadOnly Property AreaId As Guid
    Get
      Return _innerKey.Item1
    End Get
  End Property

  Public Overrides Function GetHashCode() As Integer
    Return _innerKey.GetHashCode() 'wow! such fast (enuf)
  End Function

End Structure

因此，虽然我期望有比这更好的解决方案，但我很高兴。我的表现很好。此外，令人讨厌的实用程序代码也消失了。希望这对其他被迫编写 VB 的可怜开发者来说是有用的，他们看到这篇文章。

干杯

Answer 7

我还发现 RemoveIntegerChecks MsBuild 属性会影响 /removeintchecks 防止编译器发出运行时检查的 VB 编译器属性：

  <PropertyGroup>
    <RemoveIntegerChecks>true</RemoveIntegerChecks>   
  </PropertyGroup>