在VBA中从powerpoint文件中提取所有文本

Question

我有一大堆 powerpoint 文件，我想从中提取所有文本，然后将其全部合并到一个大文本文件中。每个源 (PPT) 文件都有多个页面（幻灯片）。我不关心格式——只关心文字。

我可以通过在 PPT 中输入 ^A ^C，然后在记事本中输入 ^V 来手动完成此操作；然后在 PPT 中向下翻页，并对 Powerpoint 中的每张幻灯片重复此操作。 （太糟糕了，我不能只做一个 ^A 来抓取所有内容......然后我可以使用 sendkey 来复制/粘贴）

但是有数百个这样的 PPT，其中幻灯片数量不同。

这似乎是一件很常见的事情，但我在任何地方都找不到例子。

有人有示例代码来执行此操作吗？

Answer 1

这里有一些代码可以帮助您入门。这会将幻灯片中的所有文本转储到调试窗口。除了转储之外，它不会尝试格式化、分组或执行任何其他操作。

Sub GetAllText()
Dim p As Presentation: Set p = ActivePresentation
Dim s As Slide
Dim sh As Shape
For Each s In p.Slides
    For Each sh In s.Shapes
        If sh.HasTextFrame Then
            If sh.TextFrame.HasText Then
                Debug.Print sh.TextFrame.TextRange.Text
            End If
        End If
    Next
Next
End Sub

Answer 2

以下示例显示了根据上面给出的 Otaku 代码循环遍历文件列表的代码：

Sub test_click2()

Dim thePath As String
Dim src As String
Dim dst As String
Dim PPT As PowerPoint.Application
Dim p As PowerPoint.Presentation
Dim s As Slide
Dim sh As PowerPoint.Shape
Dim i As Integer
Dim f(10) As String

f(1) = "abc.pptx"
f(2) = "def.pptx"
f(3) = "ghi.pptx"

thePath = "C:\Work\Text parsing PPT\"

For i = 1 To 3
  src = thePath & f(i)
  dst = thePath & f(i) & ".txt"

  On Error Resume Next
  Kill dst
  Open dst For Output As #1
    Set PPT = CreateObject("PowerPoint.Application")
    PPT.Activate
    PPT.Visible = True
    'PPT.WindowState = ppWindowMinimized
    PPT.Presentations.Open filename:=src, ReadOnly:=True
    For Each s In PPT.ActivePresentation.Slides
        For Each sh In s.Shapes
            If sh.HasTextFrame Then
                If sh.TextFrame.HasText Then
                    Debug.Print sh.TextFrame.TextRange.Text
                End If
            End If
        Next
    Next
    PPT.ActivePresentation.Close
  Close #1
Next i
Set PPT = Nothing

End Sub