表单上的 KeyEvents 只能与 CTRL 结合使用

Question

代码：

Private Sub KeyHandling(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyDown
    Select Case e.KeyCode
      Case Keys.Left
        btnPrev.PerformClick()
      Case Keys.Right
        btnNext.PerformClick()
      Case Keys.Up
        btnFirst.PerformClick()
      Case Keys.Down
        btnLast.PerformClick()
    End Select
End Sub

我的表单的 KeyPreview 属性已启用。

问题：

除非我按住控制键，否则此代码不会执行任何操作。谁能解释一下吗？ :)

Answer 1

这是因为光标键在 KeyDown 事件触发之前就被提前拦截。 Winforms使用它来移动焦点，就像Tab一样。当您按住 Ctrl 键时，它不再是导航键，您的 KeyDown 事件可以看到它。

通常，您可以通过重写 IsInputKey() 来解决此问题，但如果表单有任何控件，则该方法将不起作用。如果您将 KeyPreview 设置为 true，它们可能会这样做。窗体永远不会获得焦点，控件却能。您需要放弃 KeyPreview，无论如何，它都是旧的 VB6 不合时宜的内容，您可以通过重写 ProcessCmdKey() 来捕获光标键。像这样：

Protected Overrides Function ProcessCmdKey(ByRef msg As System.Windows.Forms.Message, ByVal keyData As System.Windows.Forms.Keys) As Boolean
    If keyData = Keys.Left Then
        Console.WriteLine("left")
        Return True
    End If
    Return MyBase.ProcessCmdKey(msg, keyData)
End Function

Answer 2

我假设您的表单上有按钮。当按钮具有焦点时，用户可以通过使用表单上按钮之间的箭头按钮进行导航来更改焦点。这就是为什么按下箭头键时按钮不会收到 KeyDown 事件的原因。

以下技巧将帮助您避免这种情况。对于表单上的每个按钮，将 PreviewKeyDown 事件设置为以下内容：

Private Sub Button1_PreviewKeyDown(ByVal sender As System.Object, ByVal e As System.Windows.Forms.PreviewKeyDownEventArgs) Handles Button1.PreviewKeyDown
        e.IsInputKey = True
End Sub

Answer 3

发生的情况是箭头键正在浏览表单上的控件，非常类似于 Tab 键。每次按箭头键都会将焦点从当前活动的控件移动到与该箭头键相同的相对方向的下一个控件。

箭头键的这种解释是在比您正在处理的表单的 KeyDown 事件更高的级别上实现的。每次按键实际上都被 ProcessDialogKey 函数，它阻止该按键事件被传递到您的 KeyHandling 方法进行任何进一步的处理。

按住 Ctrl 键时一切按预期工作的原因是 ProcessDialogKey 函数不会消耗这些事件，从而允许它们传递到您的事件处理程序方法。该方法的文档告诉我们：

该方法不对包含 ALT 或 CONTROL 修饰符的击键执行任何处理。

如果您不希望箭头键在控件之间导航，而只想“单击”适当命名的按钮，那么解决方案应该是显而易见的：您需要重写 ProcessDialogKey 方法，添加您的自定义密钥处理逻辑，并返回值“True”以指示您自己处理了密钥。否则，您将继续调用基类，以免破坏 Tab 和 Enter 等内容的标准处理。同样，文档非常清晰这里：

当重写派生类中的 ProcessDialogKey 方法时，控件应返回 true 以指示它已处理该键。对于控件不处理的键，应返回调用基类的 ProcessDialogChar 方法的结果。

只需将以下代码添加到您的表单中，然后删除您现在拥有的 KeyHandling 方法：

Protected Overrides Function ProcessDialogKey(ByVal keyData As System.Windows.Forms.Keys) As Boolean
    Select Case keyData
        Case Keys.Left
            btnPrev.PerformClick()
            Return True
        Case Keys.Right
            btnNext.PerformClick()
            Return True
        Case Keys.Up
            btnFirst.PerformClick()
            Return True
        Case Keys.Down
            btnLast.PerformClick()
            Return True
    End Select

    Return MyBase.ProcessDialogKey(keyData)
End Function

Answer 4

您需要提供更多信息。

对于初学者来说，您正在处理哪个表单事件。您显示具有非标准处理程序名称的处理程序，但不显示它与哪个事件关联。您如何将其与事件关联起来？

在表单设计器中，查看“属性”窗口中的“事件”选项卡。 KeyDown 或 KeyPress 下有什么东西吗？这就是它需要的地方。

其次，它是否没有执行任何操作，因为您没有将其连接到形成键盘事件，或者因为它运行但没有执行您想要的操作？设置断点。代码会被调用吗？

根据上述问题的答案，您可能需要在处理 KeyDown 或 KeyPress 事件之间切换，具体取决于您要检测的字符。