如何使用 perl 回退一行

Question

谁能告诉我当你迭代文本文件时，如何在 Perl 中返回一行。例如，如果我看到行中的文本并且我认识到它，并且如果它被识别为特定模式，我想回到上一行做一些事情并进一步继续。

提前致谢。

Answer 1

通常，您不会返回，只需跟踪上一行：

my $previous; # contents of previous line
while (my $line = <$fh>) {
    if ($line =~ /pattern/) {
        # do something with $previous
    }
    ...
} continue {
    $previous = $line;
}

使用 continue 块可以保证即使您通过 next 绕过循环体的一部分，也会进行复制。

如果你想真正倒带，你可以使用 seek 和 tell 来完成，但它更麻烦：

my $previous = undef;    # beginning of previous line
my $current  = tell $fh; # beginning of current line
while (my $line = <$fh>) {
    if ($line =~ /pattern/ && defined $previous) {
        my $pos = tell $fh;      # save current position
        seek $fh, $previous, 0;  # seek to beginning of previous line (0 = SEEK_SET)
        print scalar <$fh>;      # do something with previous line
        seek $fh, $pos,  0;      # restore position
    }
    ...
} continue {
    $previous = $current;
    $current  = tell $fh;
}

Answer 2

my $prevline = '';
for my $line (<INFILE>) {

    # do something with the $line and have $prevline at your disposal

    $prevline = $line;
}