F# 成员约束 + ^a byref 参数

Question

在尝试了一些 F# 成员约束功能并编写如下函数之后：

let inline parse< ^a when ^a : (static member Parse: string -> ^a) > s =
    (^a: (static member Parse: string -> ^a) s)

效果非常好：

let xs = [ "123"; "456"; "999" ] |> List.map parse<int>

我正在尝试编写其他 func tryParse，它使用静态方法 TryParse 并包装将解析结果转换为 'a option 类型，以便在 F# 中提供更好的支持。像这样的东西不能编译：

let inline tryParse s =
    let mutable x = Unchecked.defaultof< ^a>
    if (^a: (static member TryParse: string * ^a byref -> bool) (s, &x))
        then Some x else None

错误是：

错误 FS0001：此表达式是 预计有类型 byref<'a> 但这里有类型 '参考

F# ref-cells 也不起作用：

let inline tryParse s =
    let x = ref Unchecked.defaultof< ^a>
    if (^a: (static member TryParse: string * ^a byref -> bool) (s, x))
        then Some x else None

我做错了什么？

Answer 1

更新

这似乎已在 F# 3.0 中修复。

旧答案：

我同意斯蒂芬的评论，这很可能是一个错误。 byref 类型有很多限制，因此它们不能很好地处理成员约束，这对我来说并不特别奇怪。这是使用反射的（丑陋的）解决方法：

type parseDel<'a> = delegate of string * 'a byref -> bool

type Parser< ^a when ^a : (static member TryParse: string * ^a byref -> bool)> private ()=
  static let parser = System.Delegate.CreateDelegate(typeof<parseDel<'a>>, typeof<'a>.GetMethod("TryParse", [|typeof<string>; typeof<'a>.MakeByRefType()|])) :?> parseDel<'a>
  static member inline ParseDel = parser

let inline tryParse (s:string) =
  let mutable x = Unchecked.defaultof< ^a>
  if Parser<_>.ParseDel.Invoke(s, &x) then
    Some x
  else None

let one : int option = tryParse "1"

Answer 2

我认为这也是一个错误，涉及成员约束和 byref 类型。我可以通过更改成员约束的签名来制作一个稍微不那么难看的反射版本：

let inline tryParse<'a when 'a : (static member TryParse : string -> 'a byref -> bool)>  s  =
    let args = [| s ; null |]
    if typeof<'a>
        .GetMethod("TryParse", [| typeof<string>; typeof< ^a>.MakeByRefType() |])
        .Invoke(null, args) = box true 
        then Some (args.[1] :?> 'a) 
        else None

这个非常接近：

let inline tryParse< ^a when ^a: (static member TryParse: string -> ^a byref -> bool)> s =
    let mutable x = Unchecked.defaultof<'a>
    if (^a: (static member TryParse: string -> ^a byref -> bool) (s, &x))
        then Some x else None

但我收到错误FS0421：此时无法使用变量“x”的地址 当我尝试编译它时。

Answer 3

这可以编译，但仍然无法按预期工作：

let inline tryParse< ^a when ^a: (static member TryParse: string -> ^a ref -> bool) > s =
  let x = ref Unchecked.defaultof< ^a>
  match (^a: (static member TryParse: string -> ^a ref -> bool )  (s, x)) with
    | false -> None
    | true -> Some(!x)

// returns [Some 0; Some 0; Some 0; null], so our tryParse is not retrieving the value from the ref
let xs = [ "1"; "456"; "999"; "a" ] |> List.map tryParse<int>

在这种特定情况下，我不会使用反射，而是在 f# 中从 Parse 中重新创建 TryParse

let inline tryParse< ^a when ^a: (static member Parse: string -> ^a) > s =
  try  
    Some(^a: (static member Parse: string -> ^a)  s)
  with
    | exn -> None

let xs = [ "1"; "456"; "999"; "a" ] |> List.map tryParse<int>