VB.NET中捕获功能键F1..F12

Question

我无法捕获我的应用程序的功能键 F1..F12。我能够捕获常规键和修饰符，例如 shift、ctrl、alt 等。

这个 问题建议KeyPreview = True，但这似乎不适用于我的应用程序。我做错了什么？

Private Sub Main_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
    Me.KeyPreview = True
    AddHandler Me.KeyDown, AddressOf KeyDownsHandler
    AddHandler Me.KeyUp, AddressOf KeyUpHandler
End Sub

Private Sub KeyUpHandler(ByVal o As Object, ByVal e As KeyEventArgs)
    e.SuppressKeyPress = True
    If e.KeyCode = Keys.F1 Then
        txtMain.AppendText("F1 was pressed!" & Environment.NewLine)
    End If
    txtMain.AppendText( _
        String.Format("'{0}' '{1}' '{2}' '{3}' {4}", e.Modifiers, e.KeyValue, e.KeyData, e.KeyCode, Environment.NewLine))
End Sub

Private Sub KeyDownHandler(ByVal o As Object, ByVal e As KeyEventArgs)
    e.SuppressKeyPress = True
    txtMain.AppendText( _
        String.Format("'{0}' '{1}' '{2}' '{3}' {4}", e.Modifiers, e.KeyValue, e.KeyData, e.KeyCode, Environment.NewLine))
End Sub

Answer 1

为了捕获按键（包括功能键），我开始使用这种模式，效果非常好：

    Protected Overrides Function ProcessCmdKey(ByRef msg As System.Windows.Forms.Message, ByVal keyData As System.Windows.Forms.Keys) As Boolean
        Select Case keyData
            Case Keys.F2
                ' Do something 

            Case Keys.F3
                ' Do more

            Case Keys.Escape
                ' Crap

            Case Else
                Return MyBase.ProcessCmdKey(msg, keyData)

        End Select

        Return True
    End Function

这将自动抑制您在 Select 语句中处理的每个键。如果您想使用 Shift、Alt 或 Ctrl 的组合，则只需或它们。当然，这适用于非常低的Form级别，这使得它独立于该表单上的任何控件。如果您不知道，它也会触发奇怪的行为，例如焦点跳跃或行为不当的控件。

Answer 2

您的代码对我有用，但您的 EventHandler 声明中有一个拼写错误。更改：

AddHandler Me.KeyDown, AddressOf KeyDownsHandler

至

AddHandler Me.KeyDown, AddressOf KeyDownHandler