在 Haskell 中解析 XML

Question

我正在尝试从定期提供带有股票市场报价的 XML 文件的网页获取数据 (示例数据）。 XML 的结构非常简单，如下所示：（

<?xml version="1.0"?>
<Contents>
  <StockQuote Symbol="PETR3" Date="21-12-2010" Time="13:20" Price="23.02" />
</Contents>

不仅如此，但这足以作为示例）。

我想将其解析为数据结构：

 data Quote = Quote { symbol :: String, 
                      date   :: Data.Time.Calendar.Day, 
                      time   :: Data.Time.LocalTime.TimeOfDay,
                      price  :: Float}

我或多或少了解 Parsec 的工作原理（在 Real World Haskell 书的水平上），并且我尝试了一些 Text.XML 库，但是我所能开发的只是一段可以工作的代码，但对于这样一个简单的任务来说太大了，而且看起来像是一个半成品的黑客，而不是最好的代码。

我对解析器和XML了解不多（我基本上知道我在RWH书中读到的内容，我以前从未使用过解析器）（我只是做统计和数值编程，我不是计算机科学家）。是否有一个 XML 解析库，我可以在其中知道模型是什么并立即提取信息，而无需手动解析每个元素，也无需解析纯字符串？

我正在考虑这样的事情：

  myParser = do cont  <- openXMLElem "Contents"
                quote <- openXMLElem "StockQuote" 
                symb <- getXMLElemField "Symbol"
                date <- getXMLElemField "Date"
                (...) 
                closequote <- closeXMLElem "StockQuote"
                closecont  <- closeXMLElem "Contents"
                return (symb, date)


  results = parse myParser "" myXMLString

我不必处理纯字符串并自己创建组合器（我很讨厌它）。

编辑：我可能需要阅读一些有关一般解析器（不仅仅是 Parsec）的内容（足以以正确的方式完成此操作）以及有关 XML 的最少内容。你们有推荐什么吗？

我必须解析的真正字符串是这样的：

 stringTest = "<?xml version=\"1.0\"?>\r\n<ComportamentoPapeis><Papel Codigo=\"PETR3\" 
 Nome=\"PETROBRAS ON\" Ibovespa=\"#\" Data=\"05/01/201100:00:00\" 
 Abertura=\"29,80\" Minimo=\"30,31\" Maximo=\"30,67\" Medio=\"30,36\" 
 Ultimo=\"30,45\" Oscilacao=\"1,89\" Minino=\"29,71\"/></ComportamentoPapeis>\r\n"

EDIT2：

我尝试了以下方法（readFloat、readQuoteTime 等...只是从字符串中读取内容的函数）。

bvspaParser :: (ArrowXml a) => a XmlTree Quote
bvspaParser = hasName "ComportamentoPapeis" /> hasName "Papel" >>> proc x -> do
   (hour,date) <- readQuoteTime ^<< getAttrValue "Data" -< x
   quoteCode   <- getAttrValue "Codigo" -< x
   openPrice   <- readFloat ^<< getAttrValue "Abertura" -< x
   minim       <- readFloat ^<< getAttrValue "Minimo" -< x
   maxim       <- readFloat ^<< getAttrValue "Maximo" -< x
   ultimo      <- readFloat ^<< getAttrValue "Ultimo" -< x
   returnA     -< Quote quoteCode (LocalTime date hour) openPrice minim maxim ultimo

docParser :: String -> IO [Quote]
docParser  str = runX $ readString [] str >>> (parseXmlDocument False) >>> bvspaParser

当我在 ghci 中调用它时：

*Main> docParser stringTest >>= print
[]

有什么问题吗？

Answer 1

有很多为 Haskell 编写的 XML 库可以为您进行解析。我推荐名为 xml 的库（请参阅 http://hackage.haskell.org/package/xml）。有了它，您可以简单地编写例如：

let contents = parseXML source
    quotes   = concatMap (findElements $ unqual "StockQuote") (onlyElems contents)
    symbols  = map (findAttr $ unqual "Symbol") quotes
print symbols

此代码片段打印 [Just "PETR3"] 作为示例 XML 的结果，并且可以轻松扩展以收集您需要的所有数据。要以您描述的风格编写程序，您应该使用 Maybe monad，因为 xml 查找函数通常返回 Maybe 字符串，表明是否可以找到标签、元素或属性。另请参阅相关问题：要使用哪个 Haskell XML 库？

Answer 2

对于简单的 xml 解析，使用 tagoup 不会出错。 http://hackage.haskell.org/package/tagsoup

Answer 3

以下代码片段使用 xml-enumerator。它将日期和时间保留为文本（解析这些内容作为读者的练习）：

{-# LANGUAGE OverloadedStrings #-}
import Text.XML.Enumerator.Parse
import Data.Text.Lazy (Text, unpack)

data Quote = Quote { symbol :: Text
                   , date   :: Text
                   , time   :: Text
                   , price  :: Float}
  deriving Show

main = parseFile_ "test.xml" (const Nothing) $ parseContents

parseContents = force "Missing Contents" $ tag'' "Contents" parseStockQuote
parseStockQuote = force "Missing StockQuote" $ flip (tag' "StockQuote") return $ do
    s <- requireAttr "Symbol"
    d <- requireAttr "Date"
    t <- requireAttr "Time"
    p <- requireAttr "Price"
    return $ Quote s d t (read $ unpack p)

Answer 4

我过去使用过Haskell XML Toolbox。类似的东西

{-# LANGUAGE Arrows #-}

quoteParser :: (ArrowXml a) => a XmlTree Quote
quoteParser =
    hasName "Contents" /> hasName "StockQuote" >>> proc x -> do
    symbol <- getAttrValue "Symbol" -< x
    date <- readTime defaultTimeLocale "%d-%m-%Y" ^<< getAttrValue "Date" -< x
    time <- readTime defaultTimeLocale "%H:%M" ^<< getAttrValue "Time" -< x
    price <- read ^<< getAttrValue "Price" -< x
    returnA -< Quote symbol date time price

parseQuoteDocument :: String -> IO (Maybe Quote)
parseQuoteDocument xml =
    liftM listToMaybe . runX . single $
    readString [] xml >>> getChildren >>> quoteParser

Answer 5

还有其他方法可以使用这个库，但是对于像这样简单的事情，我组合了一个 sax 解析器。

import Prelude as P
import Text.XML.Expat.SAX
import Data.ByteString.Lazy as L

parsexml txt = parse defaultParseOptions txt :: [SAXEvent String String]

main = do
  xml <- L.readFile "stockinfo.xml"
  return  $ P.filter stockquoteelement (parsexml xml)

  where
    stockquoteelement (StartElement "StockQuote" attrs) = True
    stockquoteelement _ = False

从那里你可以弄清楚要去哪里。您还可以使用 Text.XML.Expat.Annotated 将其解析为更像您在上面寻找的结构：

parsexml txt = parse defaultParseOptions txt :: (LNode String String, Maybe XMLParseError)

然后使用 Text.XML.Expat.Proc 浏览结构。