Mathematica 中的奇怪 Sin[x] 图

Question

我在 Mathematica 7 中随机绘制了一个 Sin[x] 函数，如下所示：

请注意大约 x = -100 处的可见缺陷。

这是缺陷部分的放大图，清楚地表明 Mathematica 由于某种原因在这些点之间使用了低得多的分辨率：

有人知道为什么会发生这种情况以及为什么只在 x = -100 时发生？

注意：同样的情况发生在 Wolfram Alpha< /a>，顺便说一下。

Answer 1

简短答案：默认绘图精度不足以满足该函数的要求，因此请按如下方式增加它

Plot[Sin[x], {x, -42 Pi, 42 Pi}, PlotPoints -> 100]

长答案：Plot 的工作原理是在有限的点集上评估函数，并用直线连接这些点。您可以使用以下命令查看 Plot 使用的点

Plot[Sin[x], {x, -42 Pi, 42 Pi}, Mesh -> All, PlotStyle -> None, 
 MeshStyle -> Black]

您可以看到，对于您的函数，计算函数的点“错过了峰值”并引入了较大的近似误差。用于选取点位置的算法非常简单，当两个峰的间距比 PlotRange/PlotPoints 更近时，可能会发生这种情况。

Plot 从 50 个等距点开始，然后在最多 MaxRecursion 阶段中插入额外的点。如果您针对 MaxRecursion 的各种设置绘制区域，您可以看到这个“洞”是如何出现的。

plot1 = Plot[Sin[x], {x, -42 Pi, 42 Pi}, PlotPoints -> 100, 
   PlotStyle -> LightGray];
Table[plot2 = 
   Plot[Sin[x], {x, -42 Pi, 42 Pi}, Mesh -> All, MeshStyle -> Thick, 
    PlotStyle -> Red, MaxRecursion -> k]; 
  Show[plot1, plot2, PlotRange -> {{-110, -90}, {-1, 1}}, 
   PlotLabel -> ("MaxRecursion " <> ToString[k])], {k, 0, 
   5}] // GraphicsColumn

根据 Stan Wagon 的 Mathematica 书籍，如果两条新线段之间的角度超过 5 度，Plot 会决定是否在两个连续点之间添加一个额外的点。在这种情况下，绘图的初始点定位很不幸，并且细分不符合该标准。您可以看到，在孔的中心插入单个评估点将产生几乎相同的绘图。

增加角度的方法用于通过使用Refinement选项来决定何时细分（我从书上得到的，但产品中似乎没有记录）

plot1 = Plot[Sin[x], {x, -42 Pi, 42 Pi}, PlotPoints -> 100, 
   PlotStyle -> LightGray];
Show[plot1, 
 Plot[Sin[x], {x, -42 Pi, 42 Pi}, Mesh -> All, MeshStyle -> Thick, 
  PlotStyle -> Red, MaxRecursion -> 3, 
   Method -> {Refinement -> {ControlValue -> 4 \[Degree]}}], 
 PlotRange -> {{-110, -90}, {-1, 1}}]

在这里你可以看到增加它从默认值 5 起 1 度修复了该孔。