RTF模板编码、XSLT编码

Question

我有以下要求，

<data>
<dataset1>
     <number>1</number>
     <name>red</name>
     <number>2</number>
     <name>Yellow</name>
     <number>3</number>
     <name>black</name>
     <number>4</number>
     <name>Violet</name> 
</dataset1>

<dataset2>
     <index>1</index>
     <index>2</index>
     <index>3</index>
     <index>4</index>
</dataset2>
</data> 

我需要循环遍历 dataset2 并获取索引值，将其与 dataset1 中的数字标签值进行比较。如果出现匹配，则显示相应名称标签的值。我需要得到 rtf 格式的输出。请提供 BI 标签或相关 xslt 代码以执行相同操作。提前致谢。

Answer 1

该样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:key name="kNameByNumber"
             match="name"
             use="preceding-sibling::number[1]"/>
    <xsl:template match="text()"/>
    <xsl:template match="index[key('kNameByNumber',.)]">
        <xsl:value-of select="concat(.,' : ',key('kNameByNumber',.),'
')"/>
    </xsl:template>
</xsl:stylesheet>

输出：

1 : red
2 : Yellow
3 : black
4 : Violet

Answer 2

我不熟悉 RTF 格式，因此无法帮助输出该格式，但是下面是一个 XSLT 1.0 样式表，它处理 dataset2/index 元素并输出任何匹配的“dataset1/name`：

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">

  <xsl:output method="text"/>

  <xsl:key name="k1" match="dataset1/name" use="preceding-sibling::number[1]"/>

  <xsl:template match="/">
    <xsl:apply-templates select="data/dataset2/index"/>
  </xsl:template>

  <xsl:template match="dataset2/index">
    <xsl:value-of select="concat('Index: ', .,
                                 '; match: ', key('k1', .), '
')"/>
  </xsl:template>

</xsl:stylesheet>

所以你的样本的输出是

Index: 1; match: red
Index: 2; match: Yellow
Index: 3; match: black
Index: 4; match: Violet