返回数组策略比较

Question

在 Fortran 中，我可以使用三种方法从子例程返回数组。第一个是通过 intent(out) 参数。第二个是通过将数组作为结果的函数。第三个是拥有一个函数，其结果是一个指向数组的指针，该指针在函数中分配。

每种方法的优点和缺点是什么？

Answer 1

我的做法是，当函数仅更改一个变量并且不产生其他输出时，使用函数返回。如果多个变量发生更改或过程执行其他操作，我会将输出变量放在参数列表中。这是一个风格的选择。使用指针可能会造成内存泄漏，尤其是作为函数参数返回的指针，因此我会避免使用此选项，除非在特定情况下有令人信服的原因。

更新：意图（输出）数组参数没有问题...不需要对数组的大小进行假设，如以下示例所示：

module example_one

implicit none

contains

subroutine two_arrays ( in_arr, out_arr )

   integer, dimension (:), intent (in) :: in_arr
   integer, dimension (:), allocatable, intent (out) :: out_arr

   integer :: i, len

   len = size (in_arr)

   allocate ( out_arr (1:len) )

   do i=1, len
      out_arr (i) = 3 * in_arr (i)
   end do

return

end subroutine two_arrays

end module example_one


program test

use example_one

implicit none

integer, dimension (1:5)  :: in_arr = [ 1, 2, 4, 5, 10 ]
integer, dimension (:), allocatable :: out_arr

write (*, *) allocated ( out_arr)
call two_arrays ( in_arr, out_arr )

write (*, *) size (out_arr)
write (*, *) out_arr

write (*, *) allocated ( out_arr)
deallocate ( out_arr )
write (*, *) allocated ( out_arr)

stop

end program test

Answer 2

1. `intent(out)` 可能是一个问题，因为您必须假设传入的数组的大小。
2. 返回数组也是一个问题，因为接收代码必须假设返回的数组的大小
3. 指向数组的指针存在与大小相关的问题以及对指针是否关联进行假设的问题。
4. 另一种方法是创建一个模块，并在该模块中有一个类型，其中包含可分配数组和详细说明数组大小的整数：

module mymodule
    type myvector
        double precision,allocatable::values(:)
        integer::length
    end type
end module

然后您的函数可以是：

function myvecreturner(someparam)
    use mymodule
    type(myvector)::myvecreturner
    integer::someparam

    allocate(myvecreturner%values(someparam))
    myvecreturner%length = someparam
end function

您可以愉快地传递这些 myvector 类型。只要记住在使用完数组后释放它们......