Lisp 示例冗余？

Question

我读过很多关于 Land of Lisp 所以我想我可以浏览一下它，看看有什么可看的。

(defun tweak-text (lst caps lit)
  (when lst
    (let ((item (car lst))
      (rest (cdr lst)))
      (cond 
       ; If item = space, then call recursively starting with ret
       ; Then, prepend the space on to the result.
       ((eq item #\space) (cons item (tweak-text rest caps lit)))
       ; if the item is an exclamation point.  Make sure that the
       ; next non-space is capitalized.
       ((member item '(#\! #\? #\.)) (cons item (tweak-text rest t lit)))
       ; if item = " then toggle whether we are in literal mode
       ((eq item #\") (tweak-text rest caps (not lit)))
       ; if literal mode, just add the item as is and continue
       (lit (cons item (tweak-text rest nil lit)))
       ; if either caps or literal mode = true capitalize it?
       ((or caps lit) (cons (char-upcase item) (tweak-text rest nil lit)))
       ; otherwise lower-case it.
       (t (cons (char-downcase item) (tweak-text rest nil nil)))))))

（评论是我的）
（仅供参考 - 方法签名是 (list-of-symbols bool-whether-to-caps bool-whether-to-treat-literally) 但作者将它们缩短为 (lst caps点燃）。）

但无论如何，问题是：
其中有 (cond... (lit ...) ((or caps lit) ...)) 。我的理解是，这将转换为 C 风格语法中的 if(lit){ ... } else if(caps || lit){...} 。那么 or 语句不是多余的吗？如果 caps 为 nil，是否存在调用 （或 caps lit） 条件的情况？

Answer 1

确实，你是对的。请参阅本书的勘误表。

第 97 页：tweak-text 函数有两个小故障，尽管它在大多数 Lisp 实现上都可以正常运行。首先，它使用 eq 函数来比较字符 - 应始终根据 ANSI 规范使用 eql 或 char-equal 等其他函数检查字符。此外，还有不必要的检查（或大写字母点亮），可以简化为大写字母。

Answer 2

我将其写为：

(defun tweak-text (list caps lit)
  (when list
    (destructuring-bind (item . rest) list
      (case item
        ((#\space)             (cons item (tweak-text rest caps lit)))
        ((#\! #\? #\.)         (cons item (tweak-text rest t    lit)))
        ((#\")                 (tweak-text rest caps (not lit)))
        (otherwise (cond (lit  (cons item (tweak-text rest nil  lit)))
                         (caps (cons (char-upcase item)
                                     (tweak-text rest nil lit)))
                         (t    (cons (char-downcase item)
                                     (tweak-text rest nil nil)))))))))

CASE 语句在角色上分派。然后 COND 语句处理其他条件。 CASE与EQL进行比较。这意味着 CASE 也适用于角色，甚至可以与多个项目进行比较。我也喜欢排列相应表达式的代码布局样式 - 这仅对等宽字体有用。这有助于我直观地检测代码中的模式，并有助于检测可以简化的代码。

DESTRCTURING-BIND 将列表分开。

为了有趣，使用 LOOP 重写：

(defun tweak-text (list)
  (loop with caps and lit

        for item in list

        when (eql item #\space)
        collect item

        else when (member item '(#\! #\? #\.))
        collect item and do (setf caps t)

        else when (eql item #\")
        do (setf lit (not lit))

        else when lit
        collect item and do (setf caps nil)

        else when caps
        collect (char-upcase item) and do (setf caps nil)

        else
        collect (char-downcase item) and
        do (setf caps nil lit nil)))