Delphi Pascal - 使用 SetFilePointerEx 和 GetFileSizeEx，在读取文件时获取物理媒体的确切大小

Question

我不知道如何使用 RTL 之外的任何 API。我一直在使用 SetFilePointer 和 GetFileSize 将物理磁盘读入缓冲区并将其转储到文件中，这样的循环可以完成 2GB 以下闪存卡的工作：

SetFilePointer(PD,0,nil,FILE_BEGIN);
SetLength(Buffer,512);
ReadFile(PD,Buffer[0],512,BytesReturned,nil);

但是 GetFileSize 有 2GB 的限制，SetFilePointer 也是如此。我完全不知道如何删除外部 API，我查看了 RTL 并在 google 上搜索了许多示例，但没有找到正确的答案。

我尝试了这个

function GetFileSizeEx(hFile: THandle; lpFileSizeHigh: Pointer): DWORD; 
    external 'kernel32';

并按照建议这个

function GetFileSizeEx(hFile: THandle; var FileSize: Int64): DWORD;
    stdcall; external 'kernel32';

但是即使我使用的是有效的磁盘句柄，该函数也会返回 0，我已经确认并使用旧的 API 转储了数据。

我使用 SetFilePointer 每 512 个字节跳转一次，使用 ReadFile 写入缓冲区，相反，当我使用 WriteFile 将初始程序加载器代码或其他内容写入磁盘时，我可以使用它进行设置。我需要能够将文件指针设置为超过 2GB。

有人可以帮助我进行外部声明并调用 GetFileSizeEx 和 SetFilePointerEx 吗？这样我就可以修改旧代码以使用 4 到 32gb 闪存卡。

Answer 1

我建议您看一下这篇 Primoz Gabrijelcic 博客文章 和他的 < href="http://gp.17slon.com/gp/gphugefile.htm">GpHugeFile 单元应该为您提供足够的指针来获取文件大小。

编辑 1 鉴于对问题的编辑，现在这看起来是一个相当愚蠢的答案。

编辑2 既然这个答案已被接受，在对 jachguate 的答案进行了大量评论之后，我觉得有责任总结一下所学到的内容。

• GetFileSize 和
  SetFilePointer 没有 2GB
  限制，它们可以用于文件
  基本上是任意大小。

• GetFileSizeEx 和
  SetFilePointerEx 非常多
  更容易使用，因为它们有效
  直接使用 64 位数量和
  错误条件要简单得多
  信号。

• OP实际上并不需要
  计算他的磁盘大小。自从
  OP正在阅读整个
  磁盘内容的大小不是
  需要。所需要的只是
  依次读取内容，直到
  什么都没有剩下。

• 事实上
  GetFileSize/GetFileSizeEx
  不支持设备句柄
  （例如物理磁盘或卷）作为
  应OP的要求。更重要的是，
  SetFilePointer/SetFilePointerEx
  无法找到此类设备的末尾
  句柄。

• 为了获取a的大小
  磁盘、卷或分区，应该
  通过该
  IOCTL_DISK_GET_LENGTH_INFO
  控制代码到
  DeviceIoControl。

最后，如果您需要使用 GetFileSizeEx< /a> 和 SetFilePointerEx那么它们可以声明如下：

function GetFileSizeEx(hFile: THandle; var lpFileSize: Int64): BOOL;
    stdcall; external 'kernel32.dll';
function SetFilePointerEx(hFile: THandle; liDistanceToMove: Int64;
    lpNewFilePointer: PInt64; dwMoveMethod: DWORD): BOOL;
    stdcall; external 'kernel32.dll';

获取这些 API 导入的一种简单方法是通过优秀的 JEDI API 库。

Answer 2

GetFileSizeEx 例程需要一个指向LARGE_INTEGER 数据类型和文档说：

如果你的编译器内置了对 64 位整数的支持，请使用 QuadPart 成员来存储 64 位整数。

幸运的是，Delphi 内置了对 64 位整数的支持，所以使用它：

var
  DriveSize: LongWord;
begin
  GetFilePointerSizeEx(PD, @DriveSize);
end;

SetFilePointerEx 需要 liDistanceToMove 的参数， lpNewFilePointer，均为 64 位整数。我的理解是它需要有符号整数，但如果我误解了文档，则您有 Unsingned 64 位整数的 UInt64 数据类型。

Answer 3

替代编码

自杀，首先你的方法是错误的，并且由于你的错误方法，你在 Windows 处理作为文件打开的磁盘驱动器的方式上遇到了一些棘手的问题。在伪代码中，您的方法似乎是：

Size = GetFileSize;
for i=0 to (Size / 512) do
begin
  Seek(i * 512);
  ReadBlock;
  WriteBlockToFile;
end;

这在功能上是正确的，但是有一种更简单的方法可以执行相同的操作，而无需实际获取 SizeOfDisk 且无需查找。当从文件（或流）中读取某些内容时，“指针”会随着您刚刚读取的数据量自动移动，因此您可以跳过“查找”。用于从文件读取数据的所有函数都会返回实际读取的数据量：您可以使用它来知道何时到达文件末尾，而无需知道文件的开始大小！

下面是如何使用 Delphi 的 TFileStream 将物理磁盘读取到文件的想法，而无需了解太多有关磁盘设备的信息：

var DiskStream, DestinationStream:TFileStream;
    Buff:array[0..512-1] of Byte;
    BuffRead:Integer;
begin
  // Open the disk for reading
  DiskStream := TFileStream.Create('\\.\PhysicalDrive0', fmOpenRead);
  try
    // Create the file
    DestinationStream := TFileStream.Create('D:\Something.IMG', fmCreate);
    try

      // Read & write in a loop; This is where all the work's done:
      BuffRead := DiskStream.Read(Buff, SizeOf(Buff));
      while BuffRead > 0 do
      begin
        DestinationStream.Write(Buff, BuffRead);
        BuffRead := DiskStream.Read(Buff, SizeOf(Buff));
      end;

    finally DestinationStream.Free;
    end;
  finally DiskStream.Free;
  end;
end;

显然，您可以以相反的方式执行类似的操作，从文件读取并写入磁盘。在编写该代码之前，我实际上尝试按照您的方式进行操作（获取文件大小等），但立即遇到了问题！显然，Windows 不知道“文件”的确切大小，除非您读取它。

作为文件打开磁盘的问题

对于我的所有测试，我使用这个简单的代码作为基础：

var F: TFileStream;
begin
  F := TFileStream.Create('\\.\PhysicalDrive0', fmOpenRead);
  try
    // Test code goes here...
  finally F.Free;
  end;
end;

第一个（明显的）要尝试的事情是：

ShowMessage(IntToStr(DiskStream.Size));

失败了。在 TFileStream 实现中依赖于调用 FileSeek，而 FileSeek 无法处理大于 2Gb 的文件。因此，我使用以下代码尝试了 GetFileSize：

var RetSize, UpperWord:DWORD;
RetSize := GetFileSize(F.Handle, @UpperWord);
ShowMessage(IntToStr(UpperWord) + ' / ' + IntToStr(RetSize));

这也失败了，即使它应该完全能够以 64 位数字形式返回文件大小！接下来我尝试使用 SetFilePointer API，因为它也应该处理 64 位数字。我想我只需使用以下代码查找文件末尾并查看结果：

var RetPos, UpperWord:DWORD;
UpperWord := 0;
RetPos := SetFilePos(F.Handle, 0, @UpperWord, FILE_END);
ShowMessage(IntToStr(UpperWord) + ' / ' + IntToStr(RetPos));

此代码也失败了！现在我在想，为什么第一个代码可以工作？显然，逐块读取效果很好，Windows 确切地知道何时停止读取！所以我认为 64 位文件处理例程的实现可能存在问题，让我们尝试以较小的增量寻找文件结尾；当我们在查找时遇到错误时，我们知道我们到达了末尾，我们将停止：

var PrevUpWord, PrevPos: DWORD;
    UpWord, Pos: DWORD;
UpWord := 0;
Pos := SetFilePointer(F.Handle, 1024, @UpWord, FILE_CURRENT); // Advance the pointer 512 bytes from it's current position
while (UpWord <> PrevUpWord) or (Pos <> PrevPos) do
begin
  PrevUpWord := UpWord;
  PrevPos := Pos;
  UpWord := 0;
  Pos := SetFilePointer(F.Handle, 1024, @UpWord, FILE_CURRENT);
end;

当尝试这段代码时，我有一个惊喜：它不会在文件的末尾停止，它只会继续下去，永远。它永远不会失败。说实话，我不确定它是否会失败……它可能不应该失败。无论如何，当我们超过文件末尾时，在该循环中执行 READ 操作会失败，因此我们可以使用非常hacky 的混合方法来处理这种情况。

解决该问题的现成例程

下面是一个现成的例程，它获取作为文件打开的物理磁盘的大小，即使 GetFileSize 失败，并且 SetFilePointer 与FILE_END 失败。将打开的 TFileStream 传递给它，它将返回 Int64 形式的大小：

function Hacky_GetStreamSize(F: TFileStream): Int64;
var Step:DWORD;

    StartPos: Int64;
    StartPos_DWORD: packed array [0..1] of DWORD absolute StartPos;

    KnownGoodPosition: Int64;
    KGP_DWORD: packed array [0..1] of DWORD absolute KnownGoodPosition;

    Dummy:DWORD;

    Block:array[0..512-1] of Byte;
begin
  // Get starting pointer position
  StartPos := 0;
  StartPos_DWORD[0] := SetFilePointer(F.Handle, 0, @StartPos_DWORD[1], FILE_CURRENT);
  try
    // Move file pointer to the first byte
    SetFilePointer(F.Handle, 0, nil, FILE_BEGIN);
    // Init
    KnownGoodPosition := 0;
    Step := 1024 * 1024 * 1024; // Initial step will be 1Gb
    while Step > 512 do
    begin
      // Try to move
      Dummy := 0;
      SetFilePointer(F.Handle, Step, @Dummy, FILE_CURRENT);
      // Test: Try to read!
      if F.Read(Block, 512) = 512 then
        begin
          // Ok! Save the last known good position
          KGP_DWORD[1] := 0;
          KGP_DWORD[0] := SetFilePointer(F.Handle, 0, @KGP_DWORD[1], FILE_CURRENT);
        end
      else
        begin
          // Read failed! Move back to the last known good position and make Step smaller
          SetFilePointer(F.Handle, KGP_DWORD[0], @KGP_DWORD[1], FILE_BEGIN);
          Step := Step div 4; // it's optimal to devide by 4
        end;
    end;
    // From here on we'll use 512 byte steps until we can't read any more
    SetFilePointer(F.Handle, KGP_DWORD[0], @KGP_DWORD[1], FILE_BEGIN);
    while F.Read(Block, 512) = 512 do
      KnownGoodPosition := KnownGoodPosition + 512;
    // Done!
    Result := KnownGoodPosition;
  finally
    // Move file pointer back to starting position
    SetFilePointer(F.Handle, StartPos_DWORD[0], @StartPos_DWORD[1], FILE_BEGIN);
  end;
end;

为了完整起见，这里有两个例程，可用于使用 Int64 来设置和获取文件指针以进行定位：

function Hacky_SetStreamPos(F: TFileStream; Pos: Int64):Int64;
var aPos:Int64;
    DWA:packed array[0..1] of DWORD absolute aPos;
const INVALID_SET_FILE_POINTER = $FFFFFFFF;
begin
  aPos := Pos;
  DWA[0] := SetFilePointer(F.Handle, DWA[0], @DWA[1], FILE_BEGIN);
  if (DWA[0] = INVALID_SET_FILE_POINTER) and (GetLastError <> NO_ERROR) then
    RaiseLastOSError;
  Result := aPos;
end;

function Hacky_GetStreamPos(F: TFileStream): Int64;
var Pos:Int64;
    DWA:packed array[0..1] of DWORD absolute Pos;
begin
  Pos := 0;
  DWA[0] := SetFilePointer(F.Handle, 0, @DWA[1], FILE_CURRENT);
  Result := Pos;
end;

最后的注释

我提供的 3 个例程作为一个参数 TFileStream，因为我用它来读取和写入文件。显然，它们只使用 TFileStream.Handle，因此可以简单地用文件句柄替换参数：功能将保持不变。

Answer 4

我知道这个线程很旧，但是...

一个小建议 - 如果您使用 Windows DeviceIoControl(...) 函数，您可以获得驱动器几何和/或分区信息，并使用它们来获取打开的驱动器或分区的总大小/长度。不再需要不断地寻找设备的末端。

这些 IOCTL 还可用于为您提供正确的卷扇区大小，您可以使用它而不是在任何地方默认为 512。

Answer 5

非常非常有用。但对于大于 4 GB 的磁盘我遇到了问题。
我解决了

   // Ok! Save the last known good position
      KGP_DWORD[1] := 0;
      KGP_DWORD[0] := SetFilePointer(F.Handle, 0, @KGP_DWORD[1], FILE_CURRENT);

用以下内容替换：：

  // Ok! Save the last known good position
  KnownGoodPosition := KnownGoodPosition + Step;

再次非常感谢...

也非常感谢 James R. Twine。我遵循使用 IOCTL_DISK_GET_DRIVE_GEOMETRY_EX 的建议并获得了磁盘尺寸，没有问题，也没有奇怪的解决方法。
这是代码：

TDISK_GEOMETRY = record
  Cylinders : Int64; //LargeInteger
  MediaType : DWORD; //MEDIA_TYPE
  TracksPerCylinder: DWORD ;
  SectorsPerTrack: DWORD ;
  BytesPerSector : DWORD ;
end;
TDISK_GEOMETRY_EX = record
  Geometry: TDISK_GEOMETRY ;
  DiskSize:  Int64; //LARGE_INTEGER ;
  Data : array[1..1000] of byte; // unknown length
end;
function get_disk_size(handle: thandle): int64;
var
  BytesReturned: DWORD;
  DISK_GEOMETRY_EX : TDISK_GEOMETRY_EX;
begin
  result := 0;
  if DeviceIOControl(handle,IOCTL_DISK_GET_DRIVE_GEOMETRY_EX,
     nil,0,@DISK_GEOMETRY_EX, sizeof(TDISK_GEOMETRY_EX),BytesReturned,nil)
  then result := DISK_GEOMETRY_EX.DiskSize;
end;