ASP.NET MVC：ActionFilterAttribute 未设置 ViewData

Question

以下 ActionFilterAttribute

Imports System.Web.Mvc

Namespace Mvc.Filters
    Public Class StopWatchFilter : Inherits ActionFilterAttribute
        Private tStart As DateTime
        Private tStop As DateTime

        Public Overrides Sub OnActionExecuting( _
            ByVal filterContext As ActionExecutingContext)

            tStart = DateTime.Now

        End Sub

        Public Overrides Sub OnResultExecuted( _
            ByVal filterContext As ResultExecutedContext)

            tStop = DateTime.Now
            filterContext.Controller.ViewData("StopWatch") = _
                ((tStop - tStart).TotalMilliseconds / 1000).ToString(".00")
        End Sub
    End Class
End Namespace

我已经编写了在控制器上设置的

''# Fixes SO code coloring
<MyApp.StopWatch()>
Function Index() As ActionResult
    Return View()
End Function

但是当我尝试在视图中显示 ViewData("StopWatch") 时，它只是空白。

我在这里错过了一些愚蠢的事情吗？

编辑：

看来我可以在 OnActinExecuting 中设置 ViewData，但在 OnResultExecuted 中不能。

那么，我到底如何才能构建一个秒表 ActionFilter 呢？

Answer 1

好的，明白了。

OnActionExecuted 允许我仍然将结果写入视图，因为结果尚未执行（其中 OnResultExecuted 已经将结果执行到视图）！

Imports System.Web.Mvc

Namespace Mvc.Filters
    Public Class StopWatchFilter : Inherits ActionFilterAttribute
        Private tStart As DateTime
        Private tStop As DateTime

        Public Overrides Sub OnActionExecuting(ByVal filterContext As ActionExecutingContext)
            tStart = DateTime.Now
        End Sub

        Public Overrides Sub OnActionExecuted(ByVal filterContext As ActionExecutedContext)
            tStop = DateTime.Now
            filterContext.Controller.ViewData("StopWatch") = ((tStop - tStart).TotalMilliseconds / 1000).ToString(".00")
        End Sub
    End Class
End Namespace

基本上，如果您将上述属性附加到任何操作，并在视图中使用 ViewData("StopWatch") 。您可以看到控制器操作执行需要多长时间。