GNU 自动工具：调试/发布目标？

Question

我一直在寻找这个有一段时间了：我目前正在将一个中型程序转换为自动工具，来自基于 Eclipse 的方法（带有 makefile）

我总是习惯于进行“调试”构建，所有调试符号且无优化，以及“发布”版本，无调试符号和最佳优化。

现在我尝试使用自动工具以某种方式复制此内容，因此我（也许）可以执行以下操作：

./configure
make debug

其中将具有所有调试符号且没有优化，并且其中：

./configure
make

将导致“发布”版本（默认）

PS：我已经阅读过有关 --enable-debug 标志/功能的信息，但在我当前的（简单）设置​​中，configure 无法识别使用它

Answer 1

ismail 的解决方案是一种常见的方法，但它存在一些严重的问题。如果用户尝试通过执行“./configure --enable-debug”来获取调试版本，则配置脚本会将 CFLAGS 设置为“-g -O2”，并且 Makefile 将使用“-g3 -O0 ... -g” -O2' 构建任何可执行文件时。在这种情况下，gcc 将使用 -O2，并且某些编译器将由于 -O 选项冲突而中止。这两种情况都不是预期的行为。

项目维护者根本不应该担心是否使用调试符号进行构建。这对于用户来说是一个问题。如果您正在构建项目并且想要进行调试构建或发布构建，则应该在配置时使用不同的选项。例如，

$ mkdir debug
$ mkdir release
$ cd debug && /path/to/configure --prefix=/dbg \
   CPPFLAGS=-DDEBUG CFLAGS="-g -O0" && make && make install
$ cd ../release && /path/to/configure CPPFLAGS=-DNDEBUG && make && make install

这将在 /dbg/bin 中安装带有“-DDEBUG”和“-g -O0”的构建（“调试构建”），并在 /usr/local/bin 中安装“release”，

您可以减少繁琐的工作使用 CONFIG_SITE 文件进行必要的键入。例如，您可以执行以下操作：

echo 'CPPFLAGS=-DDEBUG CFLAGS="-g -O0"' >> /dbg/share/config.site

然后所有将来的“configure --prefix=/dbg”调用将自动继承 CPPFLAGS 和 CFLAGS 的设置，而无需在命令行上指定。

如果作为包维护者，您希望为用户提供一种构建“调试版本”的简单方法，那么在发行版中包含一个脚本是完全可以接受的，该脚本使用适当的参数调用配置脚本并调用 制作&& make install，但是绝对没有必要在你的自动工具图元文件中添加这样的垃圾。它根本不属于那里。请注意，许多软件包都尝试添加 --enable-debug 这完全是错误的。如果用户调用configure CFLAGS="-g -O0"，但得到的构建应用了意外标志，那么您就会遇到错误，并且您的软件包已损坏。这是一种非常常见的经历，如果您维护一个包（当前正在考虑 tmux 和 curl），其中用户无法获得任何合理的人会称之为调用 configure CFLAGS="-g -O0" 后“调试构建”，那么您的包就会损坏。

使用自动工具维护包时必须始终记住的重要一点是，用户可能使用与您完全不同的工具链。用户的工具链完全有可能需要 -DMAKE_IT_A_DEBUG 或 -DUSE_DEBUG 或 -I/non/standard/path/to/headers 。也许它需要将 -O145 或 -Q 传递给编译器，或者将 -debug 传递给链接器，或者......任何东西。作为维护者，您根本没有必要的信息，甚至无法使“调试构建”一词对所有用户都有意义。因此，不要尝试，因为您可能会导致某些用户无法构建该软件。

Answer 2

在您的 configure.in 或 configure.ac 文件中添加一个子句；

AC_ARG_ENABLE(debug,
AS_HELP_STRING([--enable-debug],
               [enable debugging, default: no]),
[case "${enableval}" in
             yes) debug=true ;;
             no)  debug=false ;;
             *)   AC_MSG_ERROR([bad value ${enableval} for --enable-debug]) ;;
esac],
[debug=false])

AM_CONDITIONAL(DEBUG, test x"$debug" = x"true")

现在在您的 Makefile.in 或 Makefile.am 中；

if DEBUG
AM_CFLAGS = -g3 -O0
AM_CXXFLAGS = -g3 -O0
else
AM_CFLAGS = -O2
AM_CXXFLAGS = -O2
endif

因此，当启用调试时，您可以修改{C/CXX}FLAGS以启用调试信息。

Answer 3

使用 autotools 创建的默认 Makefile 会生成带有调试符号的二进制文件。使用 make install-strip 生成发布目标。

Answer 4

另一个在不编辑 Makefile.in 或 Makefile.am 的情况下配置 CFLAGS/CXXFLAGS 的示例。将此代码添加到您的 configure.in 或 configure.ac 文件中：

test -z "$SED" && SED=sed

AC_ARG_ENABLE([debug],
  [AS_HELP_STRING([--enable-debug],
                  [whether to include debug symbols (default is no)])],
  [enable_debug=$enableval],
  [enable_debug=no]
)

if test "x$enable_debug" = xyes; then
  dnl Remove all optimization flags from CFLAGS
  changequote({,})
  CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9s]*//g'`
  CXXFLAGS=`echo "$CXXFLAGS" | $SED -e 's/-O[0-9s]*//g'`

  CFLAGS=`echo "$CFLAGS" | $SED -e 's/-g[0-9]*//g'`
  CXXFLAGS=`echo "$CXXFLAGS" | $SED -e 's/-g[0-9]*//g'`
  changequote([,])

  CFLAGS="$CFLAGS -g -O0"
  CXXFLAGS="$CXXFLAGS -g -O0"
fi

echo "CFLAGS=$CFLAGS"

测试一下：

$ ./configure --enable-debug | grep CFLAGS