Mathematica：如何将函数应用于表的某一列

Question

我想将函数应用于表的特定列。假设 (mxn) 表的第 i 列。实际上我只想将该列中的所有元素与标量相乘，但应用通用函数也可以。

它可能只需要一些 Map 或 MapAt 命令，可能与 Transpose 结合使用，以便应用于行而不是列 - 但我无法找出寻址整个列（或行）的正确语法。

任何提示都是高度赞赏。

Answer 1

这是一个 3x3 的表格：

In[1]:= table = {{1,2,3}, {4,5,6}, {7,8,9}}
Out[1]= {{1, 2, 3}, {4, 5, 6}, {7, 8, 9}}
In[2]:= table//TableForm
Out[2]//TableForm= 1   2   3
                   4   5   6
                   7   8   9

Column 2 is table[[All, 2]]:

In[3]:= table[[All, 2]]
Out[3]= {2, 5, 8}

因此，仅修改该列很简单：

In[4]:= table[[All, 2]] = 10 * table[[All, 2]]
Out[4]= {20, 50, 80}
In[5]:= table//TableForm
Out[5]//TableForm= 1   20   3
                   4   50   6
                   7   80   9

Answer 2

例如，

ranfunc=Function[{f,mat, n},Transpose[MapAt[f /@ # &, Transpose[mat], n]]]

将 f 应用于 mat 第 n 列的每个元素。因此，例如，

ranfunc[Sin[Cos[#]] &, {{1, 2, 3}, {a, b, c}, {\[Alpha], \[Beta], \[Gamma]}}, 2]

将应用 Sin[Cos[#]]&到第二列的每个元素， while

ranfunc[s*# &, {{1, 2, 3}, {a, b, c}, {\[Alpha], \[Beta], \[Gamma]}},2]

会将第二列的每个元素乘以 s

Answer 3

一种通用方法是使用 ReplacePart

例如，将 f 应用于 mat 的第 3 列：

(mat = Array[Subscript[a, ##] &, {4, 4}]) // MatrixForm

(newmat = ReplacePart[#, 3 -> f  @#[[3]] ] & /@ mat) // MatrixForm

以下将每个条目乘以 10：

(newmat2 = ReplacePart[#, 3 -> 10 #[[3]] ] & /@ mat) // MatrixForm

然而，一种“快速”方法如下：（

mat[[All, 3 ]] *= 10

与第一种方法不同，中的所有条目mat 的第 3 列现在已修改，目前尚不清楚您是要修改现有表，还是要创建一个经过修改的新表，而保持原始表不变）

Answer 4

MapAt 函数接受以下部分规范：

MapAt[f, mat, {All, 3}]

将“f”应用于矩阵的第 3 列。

Answer 5

我发现的另一个紧凑的解决方案是使用 Map 和 MapAt：

这是一个示例矩阵：

mat={{3,4,5},{4,7,5},{2,6,7},{3,6,9}}

现在将函数 f 应用于第二列：

n=2;
Map[MapAt[f,#,n]&,mat]

结果是：

{{3,f[4],5},{4,f[7],5},{2,f[6],7},{3,f[6],9}}