在 Perl 中动态/递归构建哈希？

Question

我对 Perl 很陌生，我正在尝试递归地构建哈希，但一无所获。我尝试搜索动态构建哈希的教程，但我能找到的只是有关哈希的介绍性文章。如果您为我指出正确的方向或建议一篇不错的文章/教程，我将不胜感激。

我正在尝试从具有以下形式路径的文件中读取内容

one/two/three
four
five/six/seven/eight

，并且我想构建一个像

VAR = {
    one : {
        two : {
            three : ""
        }
    }
    four : ""
    five : {
        six : {
            seven : {
                 eight : ""
            }
        }
    }
}

我当前使用的脚本一样的哈希：

my $finalhash = {}; 
my @input = <>;

sub constructHash {
    my ($hashrf, $line) = @_; 
    @elements = split(/\//, $line);
    if(@elements > 1) {
        $hashrf->{shift @elements} = constructHash($hashrf->{$elements[0]}, @elements ); 
    } else {
        $hashrf->{shift @elements} = ""; 
    }
    return $hashrf;
}

foreach $lines (@input) {
    $finalhash = constructHash($finalhash, $lines);
}

Answer 1

我从来没有做过这样的事情，所以这种方法可能是错误的，但是好吧，这是我的镜头：

use 5.013;
use warnings;
use Data::Dumper;

sub construct {
   my $hash = shift;
   return unless @_;

   return construct($hash->{shift()} //= {}, @_);
}

my %hash;

while (<DATA>) {
   chomp;
   construct(\%hash, split m!/!);
}

say Dumper \%hash;

__DATA__
one/two/three
four
five/six/seven/eight

编辑：已修复！

EDIT2：（我认为）尾调用优化版本，因为！

sub construct {
   my $hash = shift;
   return unless @_;
   unshift @_, $hash->{shift()} //=  @_ ? {} : '';

   goto &construct;
}

Answer 2

我运行了您的代码并发现了一些问题：

• 您没有正确确定 @elements 的范围。
• 通过该递归，您将创建一个引用自身的哈希，这不是您想要的。
• 在最外层的调用中，constructHash() 的第二个参数是一个字符串，但在内部的递归调用中，您传递一个 @elements 数组，

试试这个。

use Data::Dumper;

my $finalhash = {}; 
my @input = split "\n", <<INPUT;
one/two/three
four
five/six/seven/eight
INPUT

sub constructHash {
    my $line = shift; 
    my ($first, $remainder) = split(/\//, $line,2);

    if ($remainder) {
        return { $first => constructHash($remainder) } ; 
    } else {
        return { $first , "" }; 
    }
}

foreach $lines (@input) {
    my $linehash = constructHash($lines);
    my $firstkey = (keys %$linehash)[0];
#    print Dumper $linehash;
    $finalhash->{$firstkey} = $linehash->{$firstkey};
} 


print Dumper $finalhash;

它会产生

$VAR1 = {
          'five' => {
                      'six' => {
                                 'seven' => {
                                              'eight' => ''
                                            }
                               }
                    },
          'one' => {
                     'two' => {
                                'three' => ''
                              }
                   },
          'four' => ''
        };

记住，Perl 哈希值是没有排序的。

Answer 3

基础知识：

• Perl 数据结构手册
• 自动生存

Answer 4

Data::Diver 很好地涵盖了这个利基市场，人们不应该重新发明轮子。

use strict;
use warnings;
use Data::Diver 'DiveVal';
use Data::Dumper;

my $root = {};
while ( my $line = <DATA> ) {
    chomp($line);
    DiveVal( $root, split m!/!, $line ) = '';
}
print Dumper $root;
__DATA__
one/two/three
four
five/six/seven/eight

Answer 5

这有点牵强，但它确实有效：

sub insert {
  my ($ref, $head, @tail) = @_;
  if ( @tail ) { insert( \%{$ref->{$head}}, @tail ) }
  else         {            $ref->{$head} = ''      }
}

my %hash;
chomp and insert \%hash, split( '/', $_ ) while <>;

它依赖于自动生存，这对于初学者来说确实有点高级。

可能会使您的问题的答案有点扭曲的是，您要求叶子中的空字符串，它的“类型”与节点的哈希值不同，并且需要不同的取消引用操作。