Delphi：获取路由器的MAC

Question

我正在使用 Delphi，我想确定网络中网络设备的物理 MAC 地址，在本例中是路由器本身。

我的代码：

var
  idsnmp: tidsnmp;
  val:string;
begin
  idsnmp := tidsnmp.create;
  try
    idsnmp.QuickSend('.1.3.6.1.2.1.4.22.1.2', 'public', '10.0.0.1', val);
    showmessage(val);
  finally
    idsnmp.free;
  end;
end;

其中 10.0.0.1 是我的路由器。

唉，QuickSend 总是发送“Connection Reset by Peer #10054”。我尝试修改 MIB-OID，还尝试了 IP 127.0.0.1，该连接永远不会失败。我在 Google 上没有找到任何关于 TIdSNMP 的可用教程。 ：-（

问候 丹尼尔·马歇尔

Answer 1

您可以使用SendARP函数来获取Mac地址。

检查这个样本

uses
 Windows,
 WinSock,
 SysUtils;


function SendArp(DestIP,SrcIP:ULONG;pMacAddr:pointer;PhyAddrLen:pointer) : DWord; StdCall; external 'iphlpapi.dll' name 'SendARP';


function GetMacAddr(const IPAddress: string; var ErrCode : DWORD): string;
var
MacAddr    : Array[0..5] of Byte;
DestIP     : ULONG;
PhyAddrLen : ULONG;
WSAData    : TWSAData;
begin
  Result    :='';
  WSAStartup($0101, WSAData);
  try
    ZeroMemory(@MacAddr,SizeOf(MacAddr));
    DestIP    :=inet_addr(PAnsiChar(AnsiString(IPAddress)));
    PhyAddrLen:=SizeOf(MacAddr);
    ErrCode   :=SendArp(DestIP,0,@MacAddr,@PhyAddrLen);
    if ErrCode = S_OK then
     Result:=Format('%2.2x-%2.2x-%2.2x-%2.2x-%2.2x-%2.2x',[MacAddr[0], MacAddr[1],MacAddr[2], MacAddr[3], MacAddr[4], MacAddr[5]])
  finally
    WSACleanup;
  end;
end;

Answer 2

不想抢 RRUZ 的风头，我提供了以下来自我的代码库的变体，并带有一些观察结果。我这样做是为了包含代码，作为答案而不是评论。

type
  TMacAddress = array [0..5] of Byte;

function inet_addr(const IPAddress: string): ULONG;
begin
  Result := ULONG(WinSock.inet_addr(PAnsiChar(AnsiString(IPAddress))));
end;

function SendARP(DestIP, SrcIP: ULONG; pMacAddr: Pointer; var PhyAddrLen: ULONG): DWORD; stdcall; external 'Iphlpapi.dll';

function GetMacAddress(const IPAddress: string): TMacAddress;
var
  MaxMacAddrLen: ULONG;
begin
  MaxMacAddrLen := SizeOf(Result);
  if SendARP(inet_addr(IPAddress), 0, @Result, MaxMacAddrLen)<>NO_ERROR then begin
    raise EMacAddressError.CreateFmt('Unable to do SendARP on address: ''%s''', [IPAddress]);
  end;
end;

有几点需要说明。

无需调用 WSAStartup/WSACleanup。

编辑 正如 RRUZ 在评论中指出的那样，winsock 文档没有明确将 inet_addr 从 WSAStartup/WSACleanup 中排除，因此我撤回这一点。在 Vista 上，调用 RtlIpv4StringToAddress 更简单。话虽如此，inet_addr 非常容易实现，您自己的实现可能会更容易。

其次WinSock.pas中inet_addr的声明不正确。它将返回值声明为 u_long 类型，该类型在 WinSock.pas 中定义为 Longint。这是一个有符号 4 字节整数，但它应该是一个无符号 4 字节整数 ULONG。如果没有显式转换，您可能会遇到范围错误。