drools-fusion 在应该的时候没有从工作记忆中清除事件

Question

我有以下 2 条规则：

    rule "Backup Not Succeeded For At Least 3 Days"
    @ruleId(1)
    when
        Node($id : id)
        not ( Backup(clientId == $id, $state: state == BackupStateEnum.FINISHED) over window:time( 3d ) from entry-point "Backup Stream" )
    then
        //nothing for now
    end

    rule "Prune Previous Successful Backups"
    @ruleId(2)
    when
        $prevBackup  : Backup($id : clientId,  state == BackupStateEnum.FINISHED) over window:time( 3d ) from entry-point "Backup Stream"
        $newerBackup : Backup(clientId == $id, state == BackupStateEnum.FINISHED, this after $prevBackup) over window:time( 3d ) from entry-point "Backup Stream"
    then
        drools.retract($prevBackup);
    end

以及“压力测试”，每天生成 10K 个此类备份，并模拟 50 天。鉴于上述所有规则均参考 3 天的窗口，并且系统中没有其他规则，50 天后内存中最多应有 30K 事件（较少，因为应修剪成功的事件）。然而，当我检查流入口点（WorkingMemoryEntryPoint）的内容时，我在内存中有大约 380K 事件 - 这意味着我有一些非常旧的事件没有像它们应该的那样被自动驱逐。

知识库配置为流处理模式，事件定义如下：

declare Backup
    @role( event )
    @duration ( duration )
    @timestamp( finished )
end

因此没有显式的生命周期管理。 我做错了什么？我知道它与规则 #2 有关，因为如果我删除它，我会在内存中得到 30K 事件（每天 10K * 3 天窗口）

Answer 1

根据您的描述，示例中的“after”运算符和时间窗口之间可能存在不需要的交互。

在第二条规则中，您可以尝试转储滑动窗口的使用并参数化“after”运算符，它应该达到您正在寻找的效果。示例：

 rule "Prune Previous Successful Backups"
    @ruleId(2)
    when
        $prevBackup  : Backup($id : clientId,  state == BackupStateEnum.FINISHED) from entry-point "Backup Stream"
        $newerBackup : Backup(clientId == $id, state == BackupStateEnum.FINISHED, this after[0,3d] $prevBackup) from entry-point "Backup Stream"
    then
        drools.retract($prevBackup);
    end

在任何情况下，您都可以为 Drools 团队打开 JIRA，以研究滑动窗口和无参数“after”运算符之间的交互，如您所描述的。不要忘记提及您正在使用的 Drools 版本。

埃德森

Answer 2

原来是流口水的一个错误，此后已修复。