批处理脚本 - 逐行读取

Question

我有一个日志文件，需要逐行读入并将该行传送到下一个循环。

首先，我在一个单独的文件中 grep 日志文件中的“主”字（如“错误”） - 以保持其较小。现在我需要获取单独的文件并逐行读取它 - 每行都需要进入另一个循环（在这些循环中我 grep 日志并将其分成块）但我卡在这里。

日志看起来像

xx.xx.xx.xx - - "http://www.blub.com/something/id=?searchword-yes-no" 200 - "something_else"

使用 for /f 循环，我只获取 IP 而不是完整的行。

如何管道/写入/缓冲整行？ （每行写什么并不重要）

Answer 1

试试这个：

@echo off
for /f "tokens=*" %%a in (input.txt) do (
  echo line=%%a
)
pause

由于 tokens=* 所有内容都被捕获到 %a

edit 中：
要回复您的评论，您必须这样做：

@echo off
for /f "tokens=*" %%a in (input.txt) do call :processline %%a

pause
goto :eof

:processline
echo line=%*

goto :eof

:eof

由于空格，您不能使用 %1，因为它只包含第一个空格之前的部分。并且由于该行包含引号，因此您也不能将 :processline "%%a" 与 %~1 结合使用。所以你需要使用 %* 来获取 %1 %2 %3 ...，所以整行。

Answer 2

“调用”解决方案存在一些问题。

它因许多不同的内容而失败，因为 CALL 的参数被解析器解析了两次。
这些行或多或少会产生奇怪的问题

one
two%222
three & 333
four=444
five"555"555"
six"&666
seven!777^!
the next line is empty

the end

因此您不应该在调用中使用 %%a 的值，最好将其移至变量，然后仅使用变量名称调用函数。

@echo off
SETLOCAL DisableDelayedExpansion
FOR /F "usebackq delims=" %%a in (`"findstr /n ^^ t.txt"`) do (
    set "myVar=%%a"
    call :processLine myVar
)
goto :eof

:processLine
SETLOCAL EnableDelayedExpansion
set "line=!%1!"
set "line=!line:*:=!"
echo(!line!
ENDLOCAL
goto :eof

Answer 3

这在过去对我有用，如果可以的话，它甚至会扩展文件中的环境变量。

for /F "delims=" %%a in (LogName.txt) do (
     echo %%a>>MyDestination.txt
)

Answer 4

对于那些路径中有空格的人，您将需要这样的东西：
nb 它扩展为绝对路径，而不是相对路径，因此如果您的运行目录路径中有空格，这些也算在内。

set SOURCE=path\with spaces\to\my.log
FOR /F "usebackq delims=" %%A IN ("%SOURCE%") DO (
    ECHO %%A
)

解释一下：

(path\with spaces\to\my.log)

不会解析，因为空格。
如果变成：

("path\with spaces\to\my.log")

它将被处理为字符串而不是文件路径。

"usebackq delims=" 

查看文档将允许路径用作路径（感谢 Stephan）。