使用xslt编码层次结构问题xslt v1将xml转换为xml

Question

在我的输入 xml 文件中，我在元素属性“lp”中获得了编码层次结构：

<element lp="1"/>
<element lp="1.1"/>
<element lp="2"/>
<element lp="3"/>
<element lp="3.1" />
<element lp="3.2" />
<element lp="3.2.1" />

如何将此 xml 数据转换为

<element lp="1">
   <element lp="1.1"/>
</element>
<element lp="2"/>
<element lp="3">
   <element lp="3.1"/>
   <element lp="3.2">
      <element lp="3.2.1">
   </element>
</element>

Answer 1

使用 XSLT2.0 可能有一种简单的方法可以做到这一点，但我在这里假设是 XSLT1.0。

需要注意的一件事是，您的 XML 并不严格有效，因为它缺少根元素。出于答案的目的，我假设根元素称为 elements

为了实现这一点，我认为您需要一个函数来确定元素的“级别”。这可以通过计算 @lp 属性中句号的数量来完成。在 XSLT1.0 中，我通过从文本中删除所有句号并将生成的字符串长度与原始字符串长度进行比较来完成此操作

<xsl:variable name="level" select="string-length(@lp) - string-length(translate(@lp, '.', ''))" />

因此，为了匹配顶级元素，您将执行此操作...

<xsl:apply-templates 
   select="element[string-length(@lp) - string-length(translate(@lp, '.', '')) = 0]"/>

这将匹配以下元素

<element lp="1."/>
<element lp="2."/>
<element lp="3."/>

Next ，对于每个匹配的元素，都是匹配后面元素的情况，其中

• @lp 属性以当前 @lp 属性开始
• level 比当前 level 多一级

这可以通过下面的 select 来完成

<xsl:apply-templates 
   select="following-sibling::element[substring(@lp, 1, $len) = $lp][string-length(@lp) - string-length(translate(@lp, '.', '')) = $level + 1]"/>

（注意 $len 和 $level是包含当前 @lp 属性的长度和当前级别的变量）

将其放在一起给出以下 XSLT....

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

   <xsl:template match="/elements">
      <elements>
         <xsl:apply-templates select="element[string-length(@lp) - string-length(translate(@lp, '.', '')) = 0]"/>
      </elements>
   </xsl:template>

   <xsl:template match="element">
      <xsl:variable name="lp" select="@lp"/>
      <xsl:variable name="len" select="string-length(@lp)"/>
      <xsl:variable name="level" select="$len - string-length(translate(@lp, '.', ''))" />

      <xsl:copy>
         <xsl:copy-of select="@lp"/>
         <xsl:apply-templates select="following-sibling::element[substring(@lp, 1, $len) = $lp][string-length(@lp) - string-length(translate(@lp, '.', '')) = $level + 1]"/>
      </xsl:copy>
   </xsl:template>

</xsl:stylesheet>

当应用于以下 XML 时

<elements>
    <element lp="1"/>
    <element lp="1.1"/>
    <element lp="2"/>
    <element lp="3"/>
    <element lp="3.1"/>
    <element lp="3.2"/>
    <element lp="3.2.1"/>
</elements>

产生以下输出

<elements>
    <element lp="1">
        <element lp="1.1"/>
    </element>
    <element lp="2"/>
    <element lp="3">
        <element lp="3.1"/>
        <element lp="3.2">
            <element lp="3.2.1"/>
        </element>
    </element>
</elements>

Answer 2

我认为这是之前的答案......这个样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="root">
        <result>
            <xsl:apply-templates select="element[not(contains(@lp,'.'))]"/>
        </result>
    </xsl:template>
    <xsl:template match="element">
    <xsl:variable name="vLevel" select="concat(@lp,'.')"/>
        <xsl:copy>
            <xsl:copy-of select="@*"/>
            <xsl:apply-templates
                 select="../element[starts-with(@lp,$vLevel)]
                                   [not(contains(substring-after(@lp,$vLevel),
                                                 '.'))]"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

输出：

<result>
    <element lp="1">
        <element lp="1.1"></element>
    </element>
    <element lp="2"></element>
    <element lp="3">
        <element lp="3.1"></element>
        <element lp="3.2">
            <element lp="3.2.1"></element>
        </element>
    </element>
</result>