Perl 中函数的别名

Question

在 Perl 中，如果我希望 foo() 完全执行 bar() 的操作，我可以这样做：

sub foo {return bar(@_);} 

有更好的方法吗？更接近 Ruby 的“别名”运算符吗？

Answer 1

Exporter 和类似模块采用的更好的方法是编辑符号表：（

*foo = \&bar;

编辑是因为我们正在讨论的是 Perl）

Answer 2

还有另一种方法可以做到这一点：

sub foo {goto &bar}

即使随后重新定义了 bar，这也保留了 foo 和 bar 之间的等效性。

这是一个详细的演示：

use strict;
use warnings;

sub bar {
    print "This is the original bar().\n";
}

*bar_copy = \&bar;

sub bar_link {
    goto &bar;
}

print "Executing bar_copy:\n";
bar_copy();
print "Executing bar_link:\n";
bar_link();

*bar = sub {print "This is bar(), redefined.\n"};

print "Executing bar_copy after redefinition:\n";
bar_copy();
print "Executing bar_link after redefinition:\n";
bar_link();

打印

Executing bar_copy:
This is the original bar().
Executing bar_link:
This is the original bar().
Subroutine main::bar redefined at C:\scripts\temp.pl line 19.
Executing bar_copy after redefinition:
This is the original bar().
Executing bar_link after redefinition:
This is bar(), redefined.

Answer 3

*foo = \&bar;

分配对 glob 的引用会将 glob 的该部分替换为所引用的事物。所以这使得 &foo 与 &bar 完全相同。

*foo = *bar;  # or \*bar

这也有效，但也为 foo 和 bar 之间的标量、数组、散列、文件句柄和格式设置别名。

Answer 4

由 Perlmonks 提供：

sub bar { print( "Hello World\n" ); }

BEGIN { *foo = \&bar; }

foo();
bar();