“双重检查锁定”应该如何使用？在Delphi中实现？

Question

在 C# 中，以下代码（来自此页面）可用于延迟实例化单例线程安全的类：

  class Foo {
        private volatile Helper helper = null;
        public Helper getHelper() {
            if (helper == null) {
                lock(this) {
                    if (helper == null)
                        helper = new Helper();
                }
            }
            return helper;
        }
    }

等效的线程安全Delphi代码是什么？

---

文章还提到了 Java 中双重检查锁定的两个问题：

• 有可能在辅助引用指向新创建的对象之前构造了新对象，这意味着创建了两个对象
• 有可能创建了辅助引用在对象仍在创建时指向内存块意味着将返回对不完整对象的引用

因此，虽然上述文章中的 C# 和 Java 版本的代码看起来几乎相同，但只有 C# 版本的工作原理如下预期的。如果这两个问题也存在于 Delphi 版本的双重检查锁定中，这会导致额外的问题吗？

Answer 1

使用 System.TMonitor 以线程安全的方式锁定对象实例。

function TFoo.GetHelper(): THelper;
begin
  if not Assigned(FHelper) then
  begin
    System.MonitorEnter(Self);
    try
      if not Assigned(FHelper) then
        FHelper := THelper.Create();
    finally
      System.MonitorExit(Self);
    end;
  end;
  Result := FHelper;
end;

如需进一步参考，请参阅请锁定我的对象...！来自艾伦·鲍尔。事实上，代表。我由此推断应该去艾伦那里。

Answer 2

当然，始终值得记住双重检查锁定已损坏。事实证明，这个问题并不适用于 x86 内存模型，但在未来始终值得牢记。我确信在某个时候会有 Delphi 版本，该版本将在具有受此问题影响的内存模型的平台上运行。

Embarcadero 已开始使用该模式的无锁版本以及互锁比较/交换。例如：

class function TEncoding.GetUnicode: TEncoding;
var
  LEncoding: TEncoding;
begin
  if FUnicodeEncoding = nil then
  begin
    LEncoding := TUnicodeEncoding.Create;
    if InterlockedCompareExchangePointer(Pointer(FUnicodeEncoding), LEncoding, nil) <> nil then
      LEncoding.Free;
  end;
  Result := FUnicodeEncoding;
end;

我意识到这不是问题的答案，但它并不适合评论！