将哈希值转换为 csv 文件

Question

我得到一个散列：

%hash = (
Honda.Blue => '10',
Honda.Red => '10',
Honda.Yellow => '60',
Ford.Blue => '20',
Ford.Red => '25',
Ford.Yellow => '26',
Toyota.Blue => '17',
Toyota.Red => '16',
Toyota.Yellow => '18',
);

需要将此散列转换为具有以下标头（make、blue_volume、red_volume、yellow_volume）的 csv 文件并用数据填充它

#Make,blue_volume,red_volume,yellow_volume
#Honda,10,10,60
#Ford,20,25,26
#Toyota,17,16,18


loop over %hash
     @array = split('.',$key);
     $make=$array[0];
    $line = "$make,$hash{'$make.Blue'},$hash{'$make.Red'},$hash{'$make.Yellow'}";
     push(@lines,$line);


foreach (@lines)
{
    open (LOG, '>>summary.csv');
    print LOG "$_";
    close (LOG);
}

需要帮助弄清楚此代码。

Answer 1

第一步：

• use strict; 说：
  • 在 xx.pl 第 4 行使用“strict subs”时不允许使用裸字“Honda”。

这不是创建哈希的经过批准的方式。我建议：

use strict;
use warnings;

my %hash = (
Honda  => { Blue => '10', Red => '10', Yellow => '60' },
Ford   => { Blue => '20', Red => '25', Yellow => '26' },
Toyota => { Blue => '17', Red => '16', Yellow => '18' },
);

那么，您应该使用 Text::CSV。然而，通过简单的操作来完成输出并不是那么困难。我们可以利用这样一个事实：您要求的是蓝色、红色、黄色，它们恰好按字母顺序排列：

print "make,blue_volume, red_volume,yellow_volume\n";
foreach my $make (sort keys %hash)
{
    print "$make";
    foreach my $colour (sort keys %{$hash{$make}})
    {
        print ",$hash{$make}{$colour}";
    }
    print "\n";
}

对于示例哈希，输出为：

make,blue_volume, red_volume,yellow_volume
Ford,20,25,26
Honda,10,10,60
Toyota,17,16,18

如果存在需要使用引号或其他任何内容的风险，我会使用文本::CSV。

Answer 2

使用 List::MoreUtils 的解决方案。

#!/usr/bin/env perl
use warnings;
use 5.012;
use List::MoreUtils qw/first_index/;
use Text::CSV;

my $file_out = 'my_new_file.csv';

my %hash = (
'Honda.Blue' => '10',
'Honda.Red' => '10',
'Honda.Yellow' => '60',
'Ford.Blue' => '20',
'Ford.Red' => '25',
'Ford.Yellow' => '26',
'Toyota.Blue' => '17',
'Toyota.Red' => '16',
'Toyota.Yellow' => '18',
);

my @brands = qw( Honda Ford Toyota );
my @colors = qw( Blue Red Yellow );
my @array;
for my $key ( keys %hash ) {
    my( $brand, $color ) = split /\./, $key, 2;
    my $idx_1 = first_index { $_ eq $brand } @brands;   
    my $idx_2 = first_index { $_ eq $color } @colors;
    $array[$idx_1][0] = $brand;
    $array[$idx_1][$idx_2+1] = $hash{$key};
}

my $csv = Text::CSV->new ( { binary => 1, eol => $/, auto_diag => 2 } ) 
or die Text::CSV->error_diag();
my $col_names = [ qw( Make blue_volume red_volume yellow_volume ) ];
open my $fh, '>:encoding(UTF-8)', $file_out or die $!;
$csv->print ( $fh, $col_names );
$csv->print ( $fh, $_ ) for @array;
close $fh;

Answer 3

如果您迭代哈希并为每个键创建一行，则每个创建都会重复三次；相反，通过循环 %hash、提取 make 并设置 $makes{$make} = 1，创建另一个包含所有 make 的哈希。然后循环生成您的行。

当您从 %hash 键中提取 make 时，请使用 /\./ 作为分割模式； split 总是使用一种模式，而不是一个简单的字符串（有一个奇怪的例外），并且您不想对每个字符进行拆分，这就是 split '.' 的原因。会做（谢谢，codaddict，指出这部分）。

'$make.Blue' 使用单引号，因此不会插入变量。请改用 "$make.Blue"。

将 open 和 close 分别移至 @lines 循环之前和之后。没有理由为每一行打开文件。

不要忘记每行末尾的“\n”（除非您使用 -l 标志或 say 而不是 print）。

Answer 4

查看 Text::CSV::Slurp。它将允许您将哈希值转换为 CSV，反之亦然。

Answer 5

对于那些有兴趣的人，我能够弄清楚，感谢大家的帮助！

my %hash; 
$hash{'aaa.biz'} = 'domainRegistered'; 
$hash{'aaa.com'} = 'domainRegistered'; 
$hash{'aaa.info'} = 'domainRegistered'; 
$hash{'aaa.net'} = 'domainRegistered'; 
$hash{'aaa.org'} = 'domainRegistered'; 

$hash{'bbb.biz'} = 'domainRegistered'; 
$hash{'bbb.com'} = 'domainRegistered'; 
$hash{'bbb.info'} = 'domainRegistered'; 
$hash{'bbb.org'} = 'domainRegistered'; 
$hash{'bbb.us'} = 'domainRegistered'; 

foreach $key (sort keys %hash) 
{   
    @array=split("\\.",$key);
    push (@names, $array[0]); 
}

#Extract unique values and sort
my %seen = ();
my @result = grep { !$seen{$_}++ } @names; 
@names = sort { $a <=> $b } @result;

foreach $element (@names)
{
    foreach $key (sort keys %hash) 
    {   
        @array=split("\\.",$key);
        if (@array [0] eq $element){push (@values, $hash{$key});}
    }
    $values = join(",",@values);
    $line = "$element,$values";
    undef @values;
    push(@lines,$line);
}
print join("\n",@lines);
open (summary, '>>summary.csv');
print summary join("\n",@lines);
close (summary);