在 Clojure 的嵌套映射中关联多个键/值的惯用方法是什么？

Question

想象一下您有一个这样的地图：

(def person {
  :name {
    :first-name "John"
    :middle-name "Michael"
    :last-name "Smith" }})

在一个表达式中更改与 :first-name 和 :last-name 关联的值的惯用方法是什么？

（澄清：假设您想将 :first-name 设置为“Bob”，将 :last-name 设置为“Doe”。我们还假设此映射中还有一些我们想要保留的其他值，因此从头开始构建它不是一个选项）

Answer 1

这里有几种方法。

user> (update-in person [:name] assoc :first-name "Bob" :last-name "Doe")
{:name {:middle-name "Michael", :last-name "Doe", :first-name "Bob"}}

user> (update-in person [:name] merge {:first-name "Bob" :last-name "Doe"})
{:name {:middle-name "Michael", :last-name "Doe", :first-name "Bob"}}

user> (update-in person [:name] into {:first-name "Bob" :last-name "Doe"})
{:name {:middle-name "Michael", :last-name "Doe", :first-name "Bob"}}

user> (-> person 
          (assoc-in [:name :first-name] "Bob")
          (assoc-in [:name :last-name]  "Doe"))
{:name {:middle-name "Michael", :last-name "Doe", :first-name "Bob"}}

编辑

update-in 在地图上执行递归 assoc。在这种情况下，它大致相当于：

user> (assoc person :name 
             (assoc (:name person) 
                    :first-name "Bob" 
                    :last-name "Doe"))

当您深入一系列嵌套映射时，键的重复变得越来越乏味。 update-in 的递归可以让您避免一遍又一遍地重复键（例如:name）；递归调用之间的中间结果存储在堆栈中。查看 update-in 的源代码，了解它是如何完成的。

user> (def foo {:bar {:baz {:quux 123}}})
#'user/foo

user> (assoc foo :bar 
             (assoc (:bar foo) :baz 
                    (assoc (:baz (:bar foo)) :quux 
                           (inc (:quux (:baz (:bar foo)))))))
{:bar {:baz {:quux 124}}}

user> (update-in foo [:bar :baz :quux] inc)
{:bar {:baz {:quux 124}}}

assoc 是动态的（update-in、assoc-in 以及大多数其他对 Clojure 数据结构进行操作的 Clojure 函数也是如此）。如果 assoc 到地图上，它会返回一个地图。如果您assoc到一个向量上，它会返回一个向量。查看 assoc 的源代码并查看 RT.java< /code> Clojure 源代码中的详细信息。

Answer 2

我不确定我的情况是否完全相同，但我有要应用的更改列表：

(def updates [[[:name :first-name] "Bob"] 
              [[:name :last-name] "Doe"]])

在这种情况下，您可以使用 assoc-in 减少该列表，如下所示：

(reduce #(assoc-in %1 (first %2) (second %2)) person updates)